Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|485|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-
Balloon Pong

by Foppy for Workshop #029
Hit the balloon with the ball.
Mouse
; BALLOON-PONG v1.1
; (C)2005 Foppygames

; changes in v1.1: added blobs and bumps

; Written for Wednesday Workshop #29: The Pong Challenge (www.codersworkshop.com)

Const SCREEN_WIDTH  = 800
Const SCREEN_HEIGHT = 600

Graphics(SCREEN_WIDTH,SCREEN_HEIGHT)
SetBuffer(BackBuffer())
SeedRnd(MilliSecs())

; ####################################################################################################
; CONSTANTS
; ####################################################################################################

Const KEY_ESC            = 1

Const BAT_COUNT          = 4     ; number of lives for player
Const BAT_SLOWNESS       = 4     ; slowness in updating bat position to mouse position
Const BAT_BUMP_DY#       = 0.5   ; base amount of movement when hit by ball

Const BALL_START_DY#     = 0.7   ; initial vertical speed of ball
Const BALL_SPEED_COUNT   = 16    ; number of times ball will accelerate
Const BALL_SPEED_FACTOR# = 1.1   ; factor used in acceleration
Const BALL_BUMP_FACTOR#  = 0.7   ; base amount of scaling factor when hitting upper wall or bat

; ####################################################################################################
; BAT TYPE DEFINITION AND FUNCTIONALITY
; ####################################################################################################

Type BAT
	Field fX#,fY#
	Field fW,fH
	Field fOldX#
	Field fMoved#
	Field fBumpDy#
End Type

Function BAT_create.BAT()
	bat.BAT     = New BAT
	
	bat\fX      = MouseX()
	bat\fY      = SCREEN_HEIGHT - SCREEN_HEIGHT/10
	bat\fOldX   = bat\fX
	bat\fW      = SCREEN_WIDTH/10
	bat\fH      = bat\fW/4
	bat\fBumpDy = 0
	
	Return(bat)
End Function

Function BAT_updatePosition(pBat.BAT,pSlowness)
	; new x is weighted average of old x and mouse position: 
	; old x gets weight "pSlowness", mouse position gets weight 1;
	; bigger "pSlowness" means slower update towards mouse position
	pBat\fX = (pSlowness*pBat\fOldX + MouseX())/(pSlowness + 1)

	; check that bat remains on screen	
	If (pBat\fX < 0) Then
		pBat\fX = 0
	End If
	If (pBat\fX > SCREEN_WIDTH-pBat\fW) Then
		pBat\fX = SCREEN_WIDTH-pBat\fW
	End If
	
	; store movement of bat for wave effect in main loop
	pBat\fMoved = pBat\fX - pBat\fOldX	
	
	; store updated x as old x for next round
	pBat\fOldX  = pBat\fX
	
	; update bump
	If (pBat\fBumpDy > 0) Then
		pBat\fBumpDy = pBat\fBumpDy - 0.1
	End If
End Function

Function BAT_draw(pBat.BAT)
	; draw filled rectangle
	Color(255,255,255)
	W = pBat\fW
	X = pBat\fX + pBat\fW/2 - W/2
	H = pBat\fH
	Y = pBat\fY + pBat\fH/2 - H/2 + pBat\fBumpDy
	Rect(X,Y,W,H,True)
	; draw outline of rectangle
	Color(128,128,128)
	Rect(X,Y,W,H,False)
End Function

Function BAT_bump(pBat.BAT,pBall.BALL)
	pBat\fBumpDy = BAT_BUMP_DY * pBall\fSpeedUps
End Function

; ####################################################################################################
; BALL TYPE DEFINITION AND FUNCTIONALITY
; ####################################################################################################

Type BALL
	Field fX#,fY#
	Field fDx#,fDy#
	Field fW,fH
	Field fSpeedUps
	Field fBumpFactor#
End Type

Function BALL_create.BALL()
	ball.BALL      = New BALL
	
	ball\fW        = SCREEN_WIDTH/40
	ball\fH        = ball\fW
	BALL_reset(ball)
	
	Return(ball)
End Function

Function BALL_reset(pBall.BALL)
	pBall\fX          = SCREEN_WIDTH/2 - pBall\fW/2
	pBall\fY          = SCREEN_HEIGHT/4
	pBall\fDx         = 0
	pBall\fDy         = BALL_START_DY
	pBall\fSpeedUps   = 0	
	pBall\fBumpFactor = 1
End Function

Function BALL_updatePosition%(pBall.BALL)
	; returns false when leaving at bottom of screen, true otherwise
	
	pBall\fX = pBall\fX + pBall\fDx
	pBall\fY = pBall\fY + pBall\fDy
	
	; update bump
	If (pBall\fBumpFactor < 1) Then
		pBall\fBumpFactor = pBall\fBumpFactor + 0.008
	End If
	
	; ball hits top of screen
	If (pBall\fY <= 0) Then
		pBall\fY  = -pBall\fY
		pBall\fDy = -pBall\fDy
		
		BALL_bump(pBall)
	End If
	
	; ball hits left or right sides of screen
	If (pBall\fX <= 0) Then
		pBall\fX  = -pBall\fX
		pBall\fDx = -pBall\fDx
	Else If (pBall\fX >= SCREEN_WIDTH-pBall\fW) Then
		pBall\fX  = SCREEN_WIDTH-pBall\fW-(pBall\fX-(SCREEN_WIDTH-pBall\fW))
		pBall\fDx = -pBall\fDx
	End If
	
	; ball leaves screen at bottom
	Return(Not(pBall\fY > SCREEN_HEIGHT-pBall\fH))
End Function

Function BALL_checkWithBat(pBall.BALL,pBat.BAT)
	ballX1 = pBall\fX
	ballY1 = pBall\fY
	ballX2 = pBall\fX + pBall\fW
	ballY2 = pBall\fY + pBall\fH
	batX1  = pBat\fX
	batY1  = pBat\fY
	batX2  = pBat\fX + pBat\fW
	batY2  = pBat\fY + pBat\fH
	
	; ball is in horizontal range
	If (ballX2 >= batX1 And ballX1 <= batX2) Then
		; ball hits top of bat
		If (ballY1 < batY1 And ballY2 >= batY1) Then
			pBall\fY  = pBat\fY - pBall\fH - (ballY2-batY1)
			pBall\fDy = -pBall\fDy
			
			; compute difference with center
			batCenter  = pBat\fX + pBat\fW/2
			ballCenter = pBall\fX + pBall\fW/2
			difference = ballCenter - batCenter
			
			pBall\fDx  = difference/25.0
			
			BAT_bump(pBat,pBall)
			BALL_bump(pBall)
			BALL_increaseSpeed(pBall)
		End If
	End If
End Function

Function BALL_checkWithBalloon%(pBall.BALL,pBalloon.BALLOON)
	; returns true if balloon was hit, false otherwise

	; compute horizontal and vertical differences between centers of ball and balloon
	horDiff = Abs((pBall\fX + pBall\fW/2) - (pBalloon\fX + pBalloon\fW/2))
	verDiff = Abs((pBall\fY + pBall\fH/2) - (pBalloon\fY + pBalloon\fH/2))
	; when close enough, balloon is hit
	Return((horDiff < pBalloon\fW/2) And (verDiff < pBalloon\fH/2))
End Function

Function BALL_increaseSpeed(pBall.BALL)
	If (pBall\fSpeedUps < BALL_SPEED_COUNT) Then
		pBall\fDx = pBall\fDx * BALL_SPEED_FACTOR
		pBall\fDy = pBall\fDy * BALL_SPEED_FACTOR
		pBall\fSpeedUps = pBall\fSpeedUps + 1
	End If
End Function

Function BALL_draw(pBall.BALL)
	H          = pBall\fH * pBall\fBumpFactor
	W          = pBall\fW * (1.0 + (1.0-pBall\fBumpFactor))
	extraWidth = W - pBall\fW
	Color(255,255,255)
	Oval(pBall\fX-extraWidth/2,pBall\fY,W,H,True)
	Color(128,128,128)
	Oval(pBall\fX-extraWidth/2,pBall\fY,W,H,False)
End Function

Function BALL_bump(pBall.BALL)
	pBall\fBumpFactor = BALL_BUMP_FACTOR
End Function

; ####################################################################################################
; BALLOON TYPE DEFINITION AND FUNCTIONALITY
; ####################################################################################################

Type BALLOON
	Field fX,fY
	Field fW,fH
End Type

Function BALLOON_create.BALLOON()
	balloon.BALLOON = New BALLOON
	
	balloon\fW      = SCREEN_WIDTH/20
	balloon\fH      = balloon\fW*1.5
	BALLOON_resetPosition(balloon)
	
	Return(balloon)
End Function

Function BALLOON_resetPosition(pBalloon.BALLOON)
	pBalloon\fX = Rand(0,SCREEN_WIDTH-pBalloon\fW)
	pBalloon\fY = Rand(0,SCREEN_HEIGHT/6)
End Function

Function BALLOON_draw(pBalloon.BALLOON)
	; balloon body
	Color(255,0,0)
	Oval(pBalloon\fX,pBalloon\fY,pBalloon\fW,pBalloon\fH,True)
	; thingy underneath
	Oval(pBalloon\fX+pBalloon\fW/2-pBalloon\fW/20,pBalloon\fY+pBalloon\fH,pBalloon\fW/10,pBalloon\fH/10,True)
	; piece of string
	Color(255,255,255)
	wave = 90
	For y = pBalloon\fY+pBalloon\fH To pBalloon\fY+pBalloon\fH+40
		wave = wave + 26
		Plot(pBalloon\fX+pBalloon\fW/2+Cos(wave)*3,y)
	Next	
	; highlight on balloon body
	Oval(pBalloon\fX+pBalloon\fW/6,pBalloon\fY+pBalloon\fH/6,pBalloon\fW/4,pBalloon\fH/4,True)
End Function

; ####################################################################################################
; BLOB TYPE DEFINITION AND FUNCTIONALITY
; ####################################################################################################

Type BLOB
	Field fX#,fY#
	Field fDx#,fDy#
	Field fW,fH
	Field fR,fG,fB
End Type

Function BLOB_create(pX,pY,pR,pG,pB,pDx#,pDy#)
	blob.BLOB = New BLOB
	blob\fX   = pX
	blob\fY   = pY
	blob\fR   = pR
	blob\fG   = pG
	blob\fB   = pB
	blob\fDx  = pDx
	blob\fDy  = pDy
	blob\fW   = SCREEN_WIDTH/40
	blob\fH   = blob\fW
End Function

Function BLOB_createExplosion(pX,pY,pR,pG,pB,pAmount)
	For i = 1 To pAmount
		BLOB_create(pX,pY,pR,pG,pB,Rnd(-2,2),Rnd(-3,-1))
	Next
End Function

Function BLOB_updateAll()
	For blob.BLOB = Each BLOB
		blob\fX = blob\fX + blob\fDx
		blob\fY = blob\fY + blob\fDy
		blob\fDx = blob\fDx * 0.999
		blob\fDy = blob\fDy + 0.01
		
		If (blob\fDy > 2) Then
			Delete(blob)
		End If
	Next
End Function

Function BLOB_drawAll()
	For blob.BLOB = Each BLOB
		Color(blob\fR,blob\fG,blob\fB)
		Oval(blob\fX-blob\fW/2,blob\fY-blob\fH/2,blob\fW,blob\fH,True)
	Next
End Function

; ####################################################################################################
; MISC FUNCTIONS
; ####################################################################################################

Function titleScreen%(pHiScore)
	Cls
	Color(255,255,255)
	Text(SCREEN_WIDTH/2,SCREEN_HEIGHT/20   ,"Foppygames is proud to present:",True,False)
	Text(SCREEN_WIDTH/2,SCREEN_HEIGHT/20*2 ,"BALLOON-PONG",True,False)
	Text(SCREEN_WIDTH/2,SCREEN_HEIGHT/20*4 ,"instructions: move bat with mouse - deflect ball to hit balloon",True,False)
	Text(SCREEN_WIDTH/2,SCREEN_HEIGHT/20*6 ,"click left mouse button to start or press Escape to quit",True,False)
	Text(SCREEN_WIDTH/2,SCREEN_HEIGHT/20*15,"hi-score: "+pHiScore,True,False)
	Flip
	FlushKeys
	FlushMouse
	; wait for escape or left mousebutton
	Repeat
		If (KeyHit(KEY_ESC)) Then
			Return(False)
		Else If (MouseHit(1)) Then
			Return(True)
		End If
	Forever	
End Function

; ####################################################################################################
; MAIN GAME LOOP
; ####################################################################################################

; game speed control (Swerdnik's method)
fpsCountTargetTime = MilliSecs() + 1000
renderFrames       = 0
renderFps          = 0
logicFrames        = 0
logicFps           = 0
lastTime           = MilliSecs()/3
lastNumTicks       = 1 

continue           = True
hiScore            = 0

While (continue)

	continue = titleScreen(hiScore)

	If (continue) Then
				
		score    = 0		
		lives    = BAT_COUNT
		gameOver = False
		wave     = 0
		
		; create bat, ball, and balloon
		player.BAT = BAT_create()
		BALL_create()
		balloon.BALLOON = BALLOON_create()
	
		While (Not(KeyHit(KEY_ESC) Or gameOver))				
			; get time and make sure at least 1 tick expired 
			Repeat 
				tempMS = MilliSecs()/3
				If (tempMS < lastTime) Then 
					lastTime = tempMS - lastNumTicks
				End If
				numTicks = tempMS - lastTime 
			Until numTicks > 0 
			lastTime = tempMS 

			; account for user alt-tabbing
			If (numTicks > 20) Then
				numTicks = lastNumTicks
			End If
			lastNumTicks = numTicks

			For i = 1 To numTicks
				
				; ##############
				; # game logic #
				; ##############
				
				; move bat
				BAT_updatePosition(player,BAT_SLOWNESS)
		
				For ball.BALL = Each BALL
					; move ball and check if ball leaves screen
					If (Not(BALL_updatePosition(ball))) Then
						BLOB_createExplosion(ball\fX+ball\fW/2,ball\fY+ball\fH/2,0,0,255,8)
						BALL_reset(ball)
						lives = lives - 1
					End If
					; check if ball hits bat
					BALL_checkWithBat(ball,player)					
					; check if ball hits balloon
					If (BALL_checkWithBalloon(ball,balloon)) Then
						BLOB_createExplosion(balloon\fX+balloon\fW/2,balloon\fY+balloon\fH/2,255,0,0,8)
						BALLOON_resetPosition(balloon)	
						score = score + 1
					End If
				Next
				
				; move blobs
				BLOB_updateAll()
				
				If (lives <= 0) Then
					gameOver = True
				End If
		
				; count logic frame
				logicFrames = logicFrames + 1
			Next

			; ##################
			; # game rendering #
			; ##################
	
			Cls
	
			; draw border
			Color(100,100,100)
			Rect(0,0,SCREEN_WIDTH,SCREEN_HEIGHT,False)

			; hide lowest part of rectangle by drawing black rectangle on top of it	
			Color(0,0,0)
			Rect(0,SCREEN_HEIGHT-1,SCREEN_WIDTH,1,False)
	
			; draw a sinus curve that is moved by the bat
			batMid = player\fX + player\fW/2
			Color(0,0,255)	
			For x = 0 To SCREEN_WIDTH Step 2
				waveHeight = Sin(x*4+wave)*10
				diff       = Abs(batMid - x)
				rise       = 90 - diff/2		
				If (rise < 0) Then
					rise = 0
				End If		
				rise = Sin(rise)*50.0				
				Rect(x,SCREEN_HEIGHT-62+rise-waveHeight,2,4,True)		
			Next
			wave = wave + player\fMoved*4
			If (wave >= 360) Then
				wave = 0
			End If
	
			; draw bat
			BAT_draw(player)
	
			; draw balls
			For ball.BALL = Each BALL
				BALL_draw(ball)
			Next
	
			; draw balloon
			BALLOON_draw(balloon)
	
			; draw blobs
			BLOB_drawAll()
	
			; draw score and hi-score
			Color(255,255,255)
			Text(20,SCREEN_HEIGHT-26,"score: "+Str(score),False,False)
			Text(120,SCREEN_HEIGHT-26,"hi-score: "+Str(hiScore),False,False)
			
			; draw extra lives
			For i = 0 To lives-2
				Rect(SCREEN_WIDTH-40-i*40,SCREEN_HEIGHT-20,20,5,True)
			Next
			
			Flip
	
			renderFrames = renderFrames + 1
	
			; fps stuff
			If (MilliSecs() >= fpsCountTargetTime) Then
				renderFps          = renderFrames
				renderFrames       = 0
				logicFps           = logicFrames
				logicFrames        = 0
				fpsCountTargetTime = fpsCountTargetTime + 1000
			End If
		Wend

		; update hi-score
		If (score > hiScore) Then
			hiScore = score
		End If
	End If
	
	Delete Each BAT
	Delete Each BALL
	Delete Each BALLOON
	Delete Each BLOB
Wend

End