Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|621|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

stickman

by tnt23 for Workshop #015

Jump on the evil pacman and get the key.

Cursor Keys

Click to download this entry

My game for Wednesday Workshop to prove to magicman that I know how to program, featuring a rabbit on a snowboard where you collect carrots and use the arrow keys to move and get as many points as you can in one minute.

by tnt23 for Workshop #024

Guide the Rabbit down the snow filled mountain.

Cursors

Click to download this entry

Typing Carnival

by tnt23 for Workshop #043

Type the ball to the top of the poll!

Keys

;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;Typing Carnival;;;;;;;
;;;Trinitro Studios;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;
;Wednesday Workshop XXXIII;
;;;;;;;;;;;;;;;;;;;;;;;;;;

Graphics 640,480, 16,2
SeedRnd(MilliSecs())
SetBuffer BackBuffer()
AppTitle "Typing Carnival"
;;*Constants*;;
Const a = 97
Const z = 122

;;*Fonts*;;
tahoma = LoadFont("Tahoma",26,True)
times = LoadFont("Times New Roman",25)
SetFont(tahoma)

;;*Sounds/Music*;;
Global click = LoadSound(SystemProperty("windowsdir") + "\media\start.wav")
Global chimes = LoadSound(SystemProperty("windowsdir") + "\media\chimes.wav")
Global town = PlayMusic(SystemProperty("windowsdir") + "\media\town.mid") ;;<== in case of MAV comment out this line
ChannelVolume town, 0.8 				  		;;<== and this line

;;*Globals*;;
Global x = 320,y = 430
Global ckey
Global start
Global time,min,sec
Global timest$

DisplayTitle(320,240)
FreeFont tahoma : SetFont times
SetBuffer(BackBuffer())
start = MilliSecs()
While Not KeyHit(1)
	ClsColor Rand(45),Rand(65),Rand(75)
	Cls
	Color 255,255,255
	
	DrawPole()
	DrawBall()
	UpdateInput()
	UpdateTime()
	DrawHUD(50,50)
	If y <= 0 Then GameOver()
	
	If town Then 
		If Not ChannelPlaying(town) Then 
			town = PlayMusic(SystemProperty("windowsdir") + "\media\town.mid")
		EndIf
	EndIf 
	Delay 10
	Flip
Wend : End


;;*Functions*;;
Function DisplayTitle(x,y)
	TypeText x,y, "TriNitro Studios",1,1
	If KeyDown(1) Then End
	Delay 1000
	
	PlaySound chimes
	For c = 255 To 0 Step -5
		Color c,c,c
		Text x,y, "TriNitro Studios",1,1
		If KeyDown(1) Then End
		Flip
	Next
	
	Color 255,255,255
	TypeText x,y, "Typing Carnival",1,1
	If KeyDown(1) Then End
	Delay 1000
	
	PlaySound chimes
	For c = 255 To 0 Step -5
		Color c,c,c
		Text x,y, "Typing Carnival",1,1
		If KeyDown(1) Then End
		Flip
	Next
End Function

Function TypeText(x,y,tex$,centerx=0,centery=0)
	length = Len(tex$)
	If centerx Then x = x - (StringWidth(tex$)/2)
	If centery Then y = y - (StringHeight(tex$)/2)
	
	For typewriter = 1 To length
		currentstring$ = Left(tex$,typewriter)
		Text x,y,currentstring$
		PlaySound click
		Delay 100 
		Flip 
	Next

End Function

Function DrawPole()
	Color 255,255,255
	Rect x-5,0,10,480
	Color 0,255,0
	Rect x-5,0,2,480 : Rect x+4,0,2,480
	Rect x,0,1,480
	
	Color 255,0,0
	Rect x-5,y,2,480 : Rect x+4,y,2,480
	Rect x,y,1,480
End Function

Function DrawBall()
	Color 0,0,255
	Oval x-25,y,50,50,1
End Function

Function UpdateInput()
	If GetKey() = ckey
		ckey = Rand(a,z)
		y = y - 5
	EndIf
End Function 
	
Function DrawHUD(x,y)
	Color 0,0,0
	Rect x,y,200,100,1
	Color 255,0,0
	Rect x,y,200,100,0
	Rect x,y+30,200,2,1
	
	Color 255,255,255
	Text x+100,y+2,"STATS",1
	Text x+100,y+40,"Time: " + timest$,1
	Text x+100,y+70,"Press " + Upper(Chr(ckey)),1
	
End Function 

Function UpdateTime()
	time = MilliSecs()-start
	
	dec = (time/100) Mod 10
	sec = (time/1000) Mod 60
	min = (time/1000)/60
	
	timest$ = min + ":" + sec + ":" + dec
End Function 

Function GameOver()
	Cls
	Flip
	Cls
	SetBuffer(FrontBuffer())
	Delay 200 : FlushKeys()

	Text 320,240,"Your Time: " + timest$,1,1
	WaitKey
	End
End Function

Water Balunacy!

by tnt23 for Workshop #049

Splash the water bombs on the Blue guys.

Mouse (Cursor + Enter during menus)

Graphics3D 640,480
SeedRnd MilliSecs()
SetBuffer BackBuffer()
AppTitle "Water Balunacy"

If b3d Then Gosub Initialize3D

;;constants
Const g# = 0.4 ;gravity in px/frame
Const numofdrops = 25 ; per splash
Const numofclouds = 5 ;total number of clouds
Const PLAY = 0
Const HELP = 1
Const QUIT = 2
Const menu = 0
Const ingame = 1
Const readhelp = 2
Const gameover = 3
Const b3d = True 

;;scancodes
Const up = 200
Const down = 208
Const enter = 28

;;global vars
Global level
Global score
Global lives
Global prelives
Global status 
Global s
Global dx#,dy#,gundx#,gundy#
Global angle#,ex#,ey#
Global start

;;images
Global gfxcloud = CreateImage(120,90)
Global gfxguy = CreateImage(50,80,2) : MaskImage gfxguy,255,0,255

;;fonts
Global comic = LoadFont("Comic Sans MS",48,1)
Global arial = LoadFont("Arial Black",60)
Global smarial = LoadFont("Arial Black",32)
Global vsmarial = LoadFont("Arial",16,1)

;;types
Type drop
	Field x#,y#,w,h
	Field dx#,dy#
End Type

Type balloon
	Field x#,y#
	Field dx#,dy#
End Type

Type cloud
	Field x#,y#,z
	Field dx#
End Type

Type enemy
	Field x#,y#
	Field dx#,dy#
	Field f
End Type

Initialize()
ResetEverything()
;;MAIN LOOP;;
While Not KeyDown(1)
	Cls
	Update3D()
	UpdateParts()
	Select status
	;{
	Case ingame
		UpdateBalloons()
		UpdateInput()
		UpdateLauncher()
		DrawHUD()
		UpdateAI()
	Case gameover 
		UpdateGameOver()
	Case menu
		UpdateMenu()
	Case readhelp
		PrintHelp()
	Default
		status = menu
	;}
	End Select
	
	Delay 10
	Flip
Wend:End
;;END MAIN LOOP;;

;;functions

Function CreateBalloon(x,y)
	b.balloon = New balloon
	
	b\x = x : b\y = y
	
	b\dx = gundx#*15
	b\dy = gundy#*15
End Function

Function UpdateBalloons()
	For b.balloon = Each balloon
		b\dy = b\dy + g
		b\y = b\y + b\dy
		b\x = b\x + b\dx
		
		Color 255,0,0
		Oval b\x,b\y,25,35,1
				
		If b\y > GraphicsHeight()-30 Or b\x < 0 Or b\x > GraphicsWidth()-20 Then 
			score = score-2
			CreateSplash(b\x+12.5,b\y+17.5,b\dy)
			Delete b
		EndIf 
	Next
End Function

Function CreateSplash(x,y,a)
	 For i = 0 To numofdrops
		d.drop = New drop
		d\x = x + Rand(-10,10)
		d\y = y + Rand(-10,10)
		
		d\dx = Rnd#(-3,3)
		d\dy = Rnd#(-1,-4)*(a/5)
		
		d\w = Rand(1,3) : d\h = d\w
	Next
End Function

Function UpdateParts() ;;update particles/types
	;;water drops
	For d.drop = Each drop
		d\dy = d\dy + g
		
		d\x = d\x + d\dx
		d\y = d\y + d\dy
		
		Color 0,55,255
		Oval d\x,d\y,d\w,d\h,1
		
		If d\y >= GraphicsHeight() Then Delete d
	Next
	
	;;clouds
	For c.cloud = Each cloud
		c\x = c\x + c\dx*c\z
	
		If c\x > 640 Then 
			c\x = -ImageWidth(gfxcloud)-Rand(10,50)
			c\dx = Rnd#(0.05,0.15)
		EndIf
						
		DrawImage gfxcloud, c\x,c\y
	Next
	
End Function

Function UpdateInput()
	If MouseHit(1) And MouseY()<440 Then CreateBalloon(ex#-5,ey#-5)
End Function

Function DrawCloudImage() ;;draws the cloud image
	SetBuffer ImageBuffer(gfxcloud)

	Color 200,200,200
	Oval 10,10,50,50,1

	Color 240,240,240
	Oval 45,10,40,40,1

	Color 225,225,225
	Oval 35,35,35,35,1

	Color 240,240,240
	Oval 70,10,50,50,1

	Color 210,210,210
	Oval 60,35,40,40,1
	
	Color 0,0,0
	
	For x = 0 To 120 Step 2
		For y = 0 To 90 Step 2
			Plot x,y
		Next
	Next
End Function 

Function CreateClouds() 
	;;create clouds; scatter them in sky
	For i = 0 To numofclouds-1
		c.cloud = New cloud
		
		c\y = Rand(10)
		c\dx = Rnd#(0.05,0.15)
		
		Select i+1
			Case 1
				c\z = 1
				c\x = Rand(0,200)
			Case 2
				c\z = 1
				c\x = Rand(150,280)
			Case 3
				c\z = 2
				c\x = Rand(300,500)
			Case 4
				c\z = 3
				c\x = Rand(550,600)
			Case 5
				c\z = 3
				c\x = Rand(600,630)
			Default
				RuntimeError("Could not draw clouds!")
		End Select	
	Next
End Function

Function DrawGuy()
	For f = 0 To 1
		SetBuffer ImageBuffer(gfxguy,f)
	
		Color 255,0,255
		Rect 0,0,ImageWidth(gfxguy),ImageHeight(gfxguy),1
	
		;;head
		If f Then Color 255,0,0 Else Color 0,0,255
		Oval 10,0,40,40,1
		Gray 0
		Oval 10,0,40,40,0

		;;torso
		Gray 255
		Rect 29,40,1,25,1

		;;arms
		Line 29,50,10,45
		Line 29,50,50,45

		;;legs
		Line 29,65,20,80
		Line 29,65,40,80

		;;eyes
		Gray 255
		Oval 15,5,12,12,1
		Oval 30,5,12,12,1
		
		Gray 0
		Oval 15,5,12,12,0
		Oval 30,5,12,12,0

		Oval 19,10,5,5,1
		Oval 34,10,5,5,1

		Gray 255
		Plot 20,11
		Plot 35,11

		;;mouth
		Gray 0
		Oval 19,20,20,10,0

		If f Then Color 255,0,0 Else Color 0,0,255
		Rect 19,20,20,5,1
	Next
End Function

Function Update3D()
	If b3d Then
		UpdateWorld()
		RenderWorld()
	Else
		Color 255,255,0
		Oval 560,-20,100,100,1
		
		Color 0,200,0
		Rect 0,400,640,80,1
	EndIf
End Function

Function Gray(c)
	Color c,c,c
End Function 

Function UpdateMenu()
	For i = 0 To 2
		Gray 0
		SetFont arial
		Text 320,100,"Water Balunacy!",1,1
		
		If s = i Then Color 255,60,0 Else Gray 50

		SetFont comic
		Select i
			Case play
				Text 320,200,"PLAY",1,1
			Case help
				Text 320,260,"HELP",1,1
			Case quit
				Text 320,320,"QUIT",1,1
		End Select
		
		If KeyHit(up) Then s = s - 1
		If KeyHit(down) Then s = s + 1
			
		If s > 2 Then s = 0
		If s < 0 Then s = 2	

		
		If KeyHit(enter) Then
			Select s
				Case play 
					status = ingame
				Case quit
					End
				Case help
					status = readhelp
			End Select 
		EndIf		
	Next
End Function

Function PrintHelp()
	Gray 0
	SetFont smarial
	Text 320,120,"Aim and shoot the balloons with the mouse.",1,1
	Text 320,160,"Look at the launcher at the bottom left hand",1,1
	Text 320,200,"corner of the screen. Try to hit the",1,1
	Text 320,240,"blue stick people's head but",1,1
	Text 320,280,"NOT the red ones.",1,1
	Text 320,320,"You lose 2 points each time you miss",1,1
	Text 320,360,"so click wisely!",1,1
	Text 320,420,"Hit enter to return to main menu",1,1
	
	If KeyHit(enter) Then
		FlushKeys()
		status = menu
	EndIf
End Function 

Function UpdateLauncher()
	dx# = MouseX()
	dy# = MouseY() - 480
	
	angle# = ATan2(dy,dx)
	
	If angle > -40 Then angle = -40
	If angle < -85 Then angle = -85
	
	gundx# = Cos(angle)
	gundy# = Sin(angle)
	
	ex# = gundx*100
	ey# = 480 + gundy*100
	
	Gray 255
	Line -2,478,ex-2,ey-2
	Line 0,480,ex,ey
	Line 2,482,ex+2,ey+2
End Function

Function CreateEnemies()
	f = 0
	For i = 0 To (level+Rand(0,2))-1
		e.enemy = New enemy
		
		e\y = 480-ImageHeight(gfxguy)
		e\x = Rand(140,640-ImageWidth(gfxguy))
		
		e\dx = Rnd#(1,4)
		e\f = f
		If level>2 Then f = Not f
	Next
End Function

Function UpdateAI()
	Local num_e = 0

	For e.enemy = Each enemy
		e\x = e\x + e\dx
		e\y = e\y + e\dy
		
		DrawImage gfxguy,e\x,e\y,e\f
		
		For b.balloon = Each balloon
			If RectsOverlap(b\x,b\y,25,35,e\x,e\y,ImageWidth(gfxguy),e\x+45)
				If e\f Then
					CreateSplash(b\x+12.5,b\y+17.5,b\dy)
					Delete b
					lives = lives - 1
					e\dy = 5
				Else
					CreateSplash(b\x+12.5,b\y+17.5,b\dy)
					score = score + 50 + (level*2) + (Abs(e\dx)*Rand(2,5))
					Delete b
					e\dy = 5
				EndIf
			EndIf
		Next
		
		If Not e\f Then num_e = num_e + 1
		If e\x+ImageWidth(gfxguy) > 640 Or e\x < 140 Then e\dx = -e\dx
		If e\y > 500 Then Delete e
	Next
	
	If num_e <= 0 Then
		level = level + 1
		Delete Each enemy
		CreateEnemies()
	EndIf
End Function

Function DrawHUD()
	SetFont vsmarial
	Color 0,0,0
	Text 15,70,"> Level " + level
	
	If lives < prelives And lives>0 Then
		SetFont arial
		Color 255,0,0:SetBuffer(BackBuffer())
		Text 15,90,"> Lives: " + lives: Flip
		Delay 500
		SetFont vsmarial
	EndIf
	
	Text 15,90,"> Lives: " + lives
	prelives = lives
		
	Color 0,0,0
	Text 15,110,"> Score: " + score
	
	CheckStats()
End Function

Function ResetEverything()
	score = 0
	lives = 5
	level = 0
End Function

Function CheckStats() ;;checks if player is alive
	If lives < 1 Then
		Delete Each balloon
		Delete Each enemy
		Delete Each drop
		
		SetFont comic
		start = MilliSecs()
		status = gameover
	EndIf
End Function 

Function UpdateGameOver()
	If MilliSecs()>start+5000 Then
		ResetEverything()
		status = menu
	Else
		Text 320,200,"GAME OVER",1,1
		Text 320,260,"SCORE: " + score,1,1
	EndIf
End Function 

Function Initialize()
	DrawCloudImage()
	DrawGuy()
	SetBuffer BackBuffer()
	ClsColor 128,255,255 ;;sky blue
	CreateClouds()
End Function


;;subroutines
.Initialize3D
	
	grass = CreateTexture(32,32)
	SetBuffer TextureBuffer(grass)
	;{
		Color 0,200,0
		Rect 0,0,32,32,1
		
		Color 0,160,0
		For x = 0 To 32 Step 2
			For y = 0 To 32 Step 2
				Plot x,y
			Next
		Next
	;}
	SetBuffer BackBuffer()
	
	Global cam = CreateCamera()

	Global plane = CreatePlane()
	EntityTexture plane,grass
	MoveEntity plane,0,-5,0

	Global sky = CreateSphere()
	FlipMesh sky
	ScaleEntity sky,100,100,100
	PositionEntity sky,0,50,0
	EntityColor sky,75,255,255
	
	Global sun = CreateSphere(16)
	MoveEntity sun,18,14,20
	ScaleEntity sun,4,4,4
	EntityColor sun,255,255,0
	EntityShininess sun,1 
	
	AmbientLight 210,210,210	
	Global light = CreateLight(1)
Return

Ascii Man

by tnt23 for Workshop #056

Your job is to destroy evil little cyclopse zombies. I know they look cute, but trust me, they're evil.

Cursors and Space

;;;;;;;;;;;;;;;;;;;;
;ASCII MAN 
;;;;;;;;;;;;;;;;;;;;
Const SCREENWIDTH  = 640
Const SCREENHEIGHT = 480
Initialize(SCREENWIDTH,SCREENHEIGHT)

;;;FONTS;;;
Global n = LoadFont("courier new",14)
SetFont n

;;;CONSTANTS;;;
;;scancodes
;arrows
Const up_k = 200
Const down_k = 208
Const left_k = 203
Const right_k = 205
;functions
Const F1_k = 59
;other
Const sp_k = 57
Const return_k = 28
Const enter_k = 156

;;strings
Const title$ = "N3S: ASCII Man"

Const p_health$ = "[+]"
Const p_gun$ = "[M]"
Const p_points$ = "(50)"

;;integers
Const hlprows = 20

;;;GLOBALS;;;
;;string dimensions
Global hw = StringWidth (" || MAN  ==+==") 
Global hh = StringHeight(" || MAN  ==+==")*10.5
Global mw = StringWidth ("\--- /")
Global mh = StringHeight("\--- /")*3


;;strings
Global message$

;;integers
Global hx = 5,hy
Global numaliens,numbullets
Global tx = 320-(StringWidth (title)/2)
Global ty = 240-(StringHeight(title)/2)
Global face = 1
Global it, mt, dead

;menu/ingame
Global menu = True
Global help = False
Global info

;stats
Global score,lvl
Global ammo = 00
Global health = 10

;;;FRAME TIMER;;;
Global timer = CreateTimer(60)

;;;TYPES;;;
Type bullet 
	Field x,y
	Field dx,s$
End Type

Type monster
	Field x,y
	Field dx,dy,t,bt
	Field i
End Type

Type blood
	Field x#,y#
	Field dx#,dy#
	Field s$,t
End Type

Type letter
	Field x,y
	Field dx,dy
	Field ch$
End Type

Type power
	Field x,y
	Field p$
	Field t,c
End Type

InitializeBG()
DisplayTitle()

;;;MAIN LOOP;;;
While KeyHit(1)=False And (dead And info=0)=False
	Cls 
	
	If menu Then
		UpdateTitleBG()
		
		If help Then
			DrawHelp(320,100)
			If KeyHit(enter_k) Or KeyHit(return_k)
				FlushKeys()
				help = 0
			EndIf
		Else	
			Text tx,ty,title
			Text 320,ty+25,">>>PRESS ENTER TO PLAY<<<",1
			Text 320,ty+40,"Press F1 for help",1
			Text 320,ty+55,"Press ESC to quit",1
			If KeyHit(F1_k) Then help = 1
		EndIf
		
		If KeyHit(enter_k) Or KeyHit(return_k) Then menu = 0
	Else
		If info Then
			UpdateBG()
			
			Color 255,255,255
			Text 320,240,message$,1,1
			If MilliSecs()>it+3000 Then info = 0
			

			UpdateBlood()			
			DrawHUD()
		Else	
			UpdateBG()
			DrawMan(hx,hy)
			UpdateInput()
			UpdateBullets()
			UpdateMonsters()
			UpdateBlood()
			UpdatePowers()
			DrawHUD()
				
			If numaliens <= 0 Then LevelUp()
		EndIf
	EndIf
	
	WaitTimer(timer)
	Flip 0
Wend: End 

;;;FUNCTIONS;;;
Function Initialize(w,h)
	Graphics w,h
	
	AppTitle(title)
	SetBuffer BackBuffer()
	HidePointer()
	SeedRnd(MilliSecs())
	
End Function

Function DrawMan(x,y)
	If face Then Restore man Else Restore man2
	
	For i = 0 To 13
		Read r$
			
		Select i
			Case 0 
				Color 189,123,0
			Case 2 
				Color 255,180,100
			Case 4
				Color 255,180,100
			Case 5
				Color 255,180,100
			Case 10
				Color 0,128,255
			Case 11
				Color 0,128,255 
			Case 12
				Color 0,128,255
			Default
				Color 255,255,255
		End Select

		Text hx,hy+(i*10),r$
	
	Next
	Color 255,255,255
End Function

;UPDATE BULLETS
;ALSO CHECKS COLLISIONS WITH PLAYER CHARACTER
Function UpdateBullets() 
	numbullets = 0
	For  b.bullet = Each bullet
		b\x = b\x + b\dx
		If b\s = "=" Then Color 0,255,255 Else Color 0,255,0
		Text b\x,b\y,b\s	Color 255,255,255
		
		
		;;player collisions
		If RectsOverlap(b\x,b\y,StringWidth(b\s),StringHeight(b\s), hx,hy,hw-20,hh)

			health = health - 1 
			BloodSplat(b\x,b\y,10)
			Delete b
			

			If health <= 0
				dead = True
				info = True
				message = "Game Over; Your score is " + score
				it = MilliSecs()
				Bloodsplat(hx+(hw/2),hy+(hh/2),200)
			
EndIf
			
			Return
		EndIf
					
		numbullets = numbullets + 1
		If b\x > 640 Or b\x<0 Then Delete b
	Next
End Function

Function UpdateInput()
	If ammo > 0 Then
		If KeyDown(sp_k) And MilliSecs()>mt+100 Then
			b.bullet = New bullet
			
mt = MilliSecs()
			ammo = ammo - 1
			If face Then	
				b\x = hx + hw
				b\y = hy + StringHeight("|||")*6
				b\dx = 25
				b\s = "o>"

				Color 255,255,0
				Text b\x+3,b\y-3,"*"		
			Else
				b\x = hx
				b\y = hy + StringHeight("|||")*6
				b\dx = -25
				b\s = "<o"
			
				Color 255,255,0
				Text b\x-8,b\y-3,"*"		
			EndIf
		EndIf
	Else
		If KeyHit(sp_k) Then
			b.bullet = New bullet
			If face Then	
				b\x = hx + hw
				b\y = hy + StringHeight("|||")*6
				b\dx = 25
				b\s = "o>"

				Color 255,255,0
				Text b\x+3,b\y-3,"*"		
			Else
				b\x = hx
				b\y = hy + StringHeight("|||")*6
				b\dx = -25
				b\s = "<o"
			
				Color 255,255,0
				Text b\x-8,b\y-3,"*"		
			EndIf
		EndIf
	
	EndIf
	
	If KeyDown(up_k) Then
		If hy>-(hh/2) Then hy = hy - 6
	ElseIf KeyDown(down_k)
		If hy <480-(hh/2) Then hy = hy + 6
	EndIf
	
	If KeyDown(left_k) Then
		face = 0 
		If hx>0 Then hx = hx - 6
	ElseIf KeyDown(right_k) Then
		face = 1
		If hx<640-hw Then hx = hx + 6
	EndIf
End Function

Function LevelUp()
	Delete Each bullet
	Delete Each monster
	hx = 0 : hy = 0
	lvl = lvl + 1
	
	If health<10 Then health = health + 1
		
	Repeat 
		add = Rand(-1,2)
		Local num = lvl + add
	Until num<>0
		
	For i = 0 To num-1
		m.monster = New monster
		m\x = Rand(hx+hw+20,640-mw-25)
		m\y = Rand(20,480-(mh*2)-(hh/2))
		
		m\i = Rand(3000,5000)
		
		Repeat	
			m\dx = Rand(-5,5)
			m\dy = Rand(-5,5)
		Until m\dx<>0 And m\dy<>0
		
		m\bt = MilliSecs()
	Next
	
	info = True
	it = MilliSecs()
	message = "Now entering Level " + lvl
End Function 

Function DrawAlien(x,y)
	Restore alien
	
	Color 0,255,0
	For i = 0 To 3
		Read r$
		Text x,y+(i*10),r$
	Next
	
	Color 255,255,255
End Function 


Function UpdateMonsters() ;;updates monsters&AI n draws 'em
	numaliens = 0
	For m.monster = Each monster
		m\x = m\x + m\dx
		m\y = m\y + m\dy
		
		If m\x >= 640-(mw*2) Or m\x<=10 Or (m\t< MilliSecs()+3000 And Rand(50)=25)
			m\dx = -m\dx
			m\t=MilliSecs()
		EndIf
		
		If m\y >= 480-(mh*2)-(hh/2) Or m\y<=10 Or (m\t< MilliSecs()+3000 And Rand(50)=25)
			m\dy = -m\dy
			m\t=MilliSecs()
		EndIf
		
		If m\dx = 0 Then m\dx = Rand(-5,5)
		If m\dy = 0 Then m\dy = Rand(-5,5)
		DrawAlien(m\x,m\y)
	
		numaliens = numaliens + 1
		qwerty = Rand(0,5)
		If MilliSecs()>m\bt+m\i-(level*2) And Rand(0,10)=qwerty And numbullets<3 Then
			b.bullet = New bullet
			b\x = m\x
			b\y = m\y + StringHeight("|")
			b\dx = -5
			b\s = "="
			m\bt = MilliSecs()
		
		EndIf
		
		For b.bullet = Each bullet
			If RectsOverlap(b\x,b\y,StringWidth(b\s),StringHeight(b\s),m\x,m\y,mw,mh)
				If b\s = "o>" Or b\s = "<o"
					If Rand(1,10) = 5 Then 
						p.power = New power
						p\x = m\x: p\y = m\y
						
p\t = MilliSecs()
						p\c = 255
						
						temp = Rand(1,3)
						
						Select temp
							Case 1
								p\p = p_health
							Case 2
								p\p = p_gun
							Case 3
								p\p = p_points
						End Select
					EndIf
					
					BloodSplat(m\x,m\y,10)
					Delete b
					Delete m
					score = score + 10			
					numaliens = numaliens-1
					Exit
				EndIf
			EndIf
		Next
	Next
End Function

Function BloodSplat(x,y,parts=10)
	For i = 0 To parts
		bl.blood = New blood
		bl\x = x : bl\y = y
		
		bl\dx = Sin(Rnd#(0,359))*Rnd#(-2,5)
		bl\dy = Cos(Rnd#(0,359))*Rnd#(-5,5)

		bl\t = MilliSecs()
		
		q=Rand(0,1)
		
		If q Then bl\s = "." Else bl\s=","
	Next
End Function

Function UpdateBlood()
	For bl.blood = Each blood 
		bl\x = bl\x + bl\dx
		bl\y = bl\y + bl\dy
		
		bl\dy = bl\dy + 0.1
		
		Color 255,0,0
		Text bl\x,bl\y,bl\s
		Color 255,255,255
		
		If MilliSecs() > bl\t + Rand(3000,5000) Then Delete bl
	Next
End Function

Function InitializeBG()
	For i = 0 To 19
	
	l.letter = New letter
	
		l\x = Rand(0,630)
		l\y = Rand(0,470)
		
		l\dx = Rand(-4,-10)
		l\dy = Rand(4,10)
				
		l\ch = Chr$(Rand(33,122))
	Next
End Function

Function UpdateTitleBG()
	For l.letter = Each letter
		l\y = l\y + l\dy
		
		If l\y > 480 Then 
			
			l\x = Rand(0,630)
			l\y = -10
		EndIf
		
		Color 0,150,0
		Text l\x,l\y,l\ch
		Color 255,255,255
	Next
End Function

Function UpdateBG()
	For l.letter = Each letter
		l\x = l\x + l\dx
		
		If l\x < 0 Then 
			l\x = 660
			l\y = Rand(0,470)
		EndIf
		
		Color 0,150,0
		Text l\x,l\y,l\ch
		Color 255,255,255
	Next
End Function

Function DisplayTitle()
	
	Local temp$ = ""
	
	Local cs$ = ""
	For i = 1 To Len(title)
		cs = Mid(title,i,1)
		
		x = tx+StringWidth(temp)
		
		For y = 0 To ty Step 20
			Cls
			
			updatetitleBG()
			
			Text tx,ty,temp
			Text x,y,cs
			If KeyHit(1) Then End
			Flip
		Next
		temp = temp + cs$
	Next

	
	m = MilliSecs()
	
	c = 255
	Repeat
		Cls
		updatetitleBG()
		c = c - 5
		Color c,c,c
		Text tx,ty,title
		If KeyHit(1) Then End
		Flip
	Until c<=100
		
End Function

Function DrawHelp(x,y)
	Restore help
	
	For i = 0 To hlprows-1
		Read r$
		
		Text x,y+ay,r$,1
		ay = ay + StringHeight(r$)
	Next
End Function

Function DrawHUD()
	
	Local x = 500
	Text x,0,"Score: " + score
	If health>0 Then 
		Text x,10,"Health: " + String$("|",health)
	Else
		Text x,10,"Health: DEAD"
	EndIf
	If ammo Then Text x,20,"Ammo: " + ammo Else Text x,20,"Ammo: Infinite"
End Function

Function UpdatePowers()
	For p.power = Each power
		
		
If MilliSecs()>p\t+3000 Then p\c = p\c - 1
		
		Color p\c,p\c,0
		Text p\x,p\y,p\p
		
		Color 255,255,255
		
		If RectsOverlap(p\x,p\y,StringWidth(p\p),StringHeight(p\p),hx,hy,hw,hh)
			Select p\p
				Case p_health
					health = 10
				Case p_points
					score = score + 50
				Case p_gun
					ammo = ammo + 100
			End Select
			Delete p
			Return
		EndIf
		
		If p\c < 5 Then Delete p
	Next
End Function

		
;;;DATA;;;

.man 
Data "/======\      "
Data "|      ..     "
Data "|       >     "
Data "|     \_|     "
Data "\_______/     "
Data "   |  |       "
Data "  /-  - \     "
Data " ||ASCII |    "
Data " || MAN  ==+=="
Data " uu      | || "
Data "  |  ^   |    "
Data " /  / \  \    "
Data " |  |  |  |   "
Data "<<__    __>>  "

.man2 
Data "     /======\ "
Data "    ..       |"
Data "    <        |"
Data "    |_/      |"
Data "    \_______/ "
Data "       |  |   "
Data "     /-  - \  "
Data "    |ASCII || "
Data "==+==  MAN || "
Data " || |      uu "
Data "    |   ^   | "
Data "    /  / \  \ "
Data "   |  |  |  | "
Data "  <<__    __>>"

.alien
Data "/\_/\ "
Data "|(.) |"
Data "| ^  |" 
Data "\--- /"

.help
Data "Welcome to ASCII Man!"
Data ""
Data "You play as the text based superhero, ASCII Man.           "
Data "Your job is to destroy evil little cyclopse zombies. I know"
Data "they look cute, but trust me, they're evil.                "

Data ""
Data "Levelling Up"
Data "Level up by destroying all the monsters in the current   "
Data "level. When you level up, you are awarded one life point."
Data ""
Data "Controls"
Data "Move with the arrow keys and shoot with space."
Data ""
Data "Pickups"
Data "[+]  - Health - Restores you to full health           "
Data "[M]  - Machine Gun - Gives you 100 machine gun bullets"
Data "(50) - Adds 50 points to your score.                  "
Data ""
Data ""
Data "<<<PRESS ENTER TO RETURN TO MAIN MENU>>>"