Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|618|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Vortex Game

by Jayenkai for Workshop #001

Shoot the oncoming enemies

Cursors and Space

;THE SUPER FLASHY VORTEX GAME
;A Game with only 5 Draw Commands per frame

Graphics 640,480,0,2
SetBuffer BackBuffer()



Dim baddy(17,2)
Dim bullet(17,2)


.restart

.TitleScreen
Repeat
Cls
Text 320,240,"THE SUPER FLASHY VORTEX GAME",1,1								;1
Text 320,280,"Hit Space to Start",1,1										;2
Text 320,440,"Disclaimer : This game contains flashing lines, and is",1,1	;3
Text 320,460,"unsuitable for people with photosensitive epilepsy",1,1		;4
Text 320,340,"Hi-Score : "+hiscore,1,1										;5
Flip
If KeyDown(1) Then End
Until KeyDown(57)


plra=0
dead=0
score=0
hiscore=0
mudown=0
target=250

For n=0 To 17
baddy(n,1)=Rand(0,1800)
baddy(n,2)=Rand(-2000,0)
Next
badspd=1

Repeat

ang=ang+1
n=n+1
If ang=>16 And n=>17 Then Cls:ang=ang-16:n=0
atx=320+(Sin(ang*20)*300)
aty=240+(Cos(ang*20)*220)
atx2=320+(Sin((ang+1)*20)*300)
aty2=240+(Cos((ang+1)*20)*220)
Color 0,180,0
Line atx,aty,320,240										;1 First object per frame = Background Drawn Outwards
Line atx,aty,atx2,aty2										;2 Second object per frame = Background Outline

Color 0,150,255
plra=plra+KeyDown(203)-KeyDown(205)
Rect 318+(Sin(plra/5)*300),238+(Cos(plra/5)*220),4,4,0		;3 Third object per frame = Rectangle for Player

If KeyDown(200)=0 Then mudown=0

If KeyDown(200) And mudown=0
mudown=1
free=-1
For b=0 To 4
If bullet(b,2)<=0 Then free=b
Next
If free>-1 Then bullet(free,2)=3000:bullet(free,1)=plra
EndIf


If n<18
Color 250,00,0
baddy(n,2)=baddy(n,2)+badspd
If baddy(n,2)>3000 Then dead=1
If baddy(n,2)>0
baddy(n,1)=baddy(n,1)+Rand(-4,4)

an=baddy(n,1)
dx=(baddy(n,2)*300)/3000
dy=(baddy(n,2)*220)/3000
x=320+(Sin(an/5)*dx)
y=240+(Cos(an/5)*dy)
Rect x-2,y-2,4,4,0											;4 Fourth object per frame = Rectangle for Baddy
EndIf

Color 60,255,60
bullet(n,2)=bullet(n,2)-32
If bullet(n,2)>0
an=bullet(n,1)
dx=(bullet(n,2)*300)/3000
dy=(bullet(n,2)*220)/3000
x=320+(Sin(an/5)*dx)
y=240+(Cos(an/5)*dy)

Rect x-2,y-2,4,4,0

For b=0 To 17
If baddy(b,2)>0
an=baddy(b,1)
dx=(baddy(b,2)*300)/3000
dy=(baddy(b,2)*220)/3000
x2=320+(Sin(an/5)*dx)
y2=240+(Cos(an/5)*dy)

If Abs(x2-x)<6 And Abs(y2-y)<6
baddy(b,2)=Rand(-2000,0):score=score+10::DebugLog "score "+score:If score=>target Then badspd=badspd+1:target=target+250
EndIf
EndIf
Next

EndIf



EndIf




Flip False


;	If you would like to check my code, uncomment the following line..
;Flip:Cls:Delay 25

If KeyDown(1) Then dead=9
Until dead>0


Text 320,240,"They Killed You",1,1			;1
Text 320,280,"You scored "+score,1,1		;2
Text 320,320,"Hit Space to continue",1,1	;3
Flip
If score>hiscore Then hiscore=score
If dead=9 Then End
Repeat:Until KeyDown(57)
Repeat:Until KeyDown(57)=0
Goto restart