Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|690|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-
Intergalactic Ascii Warriors

by Jayenkai for Workshop #112
Zap the bad guys.
Cursors and Z/X
Graphics 800,600,32,2
SetBuffer BackBuffer()

Dim plev$(10)
plev$(1)="/O\"			;Slow, single shot fire
plev$(2)="|/O\|"		;+ Doubleshot
plev$(3)="-|/O\|-"		;+ Sideshot
plev$(4)="\|-O-|/"		;/ Diagonal Fire
plev$(5)="-\|-O-|/-"	;+ Sideshot
plev$(6)="/\|-O-|/\"	;/ Backfire
plev$(7)="/\|-^-|/\"	;+ Faster Single Shot
plev$(8)="/\-|^|-/\"	;+ Thinner Double Shot
plev$(9)="/\-/^\-/\"		;+ Missiles
plev$(10)="/\-m^m-/\"		;+ Speed of a Hawk


SeedRnd MilliSecs()

SetFont LoadFont("Courier",14,1)

MyLev=1

Global plrx#,plry#,plrxa#,plrya#

Type kup
	Field x
	Field y
	Field t
End Type

Type die
	Field T
	Field Health#
	Field R,G,B
	Field x#,y#
	Field X1#,Y1#
	Field X2#,Y2#
	Field X3#,Y3#
	Field X4#,Y4#
	Field Frame#
	Field speed#
End Type

Type let
	Field x#,y#,txt$,gx#,gy#,u,pow
End Type

Score=0
Lives=3
NextUp=0


Dim bType$(10)
bType$(1)="\_V_/"
bType$(2)="*-v-*"
bType$(3)="!o!"
bType$(4)="\@/"
bType$(5)="\-(O)-/"
bType$(6)="}x{"
bType$(7)="v-o-v"
bType$(8)="<+o+>"
bType$(9)="~o~"
bType$(10)="|<o>|"


Dim trig(10)


shoot=0

plrx=400
plry=580
Tdead=120



Repeat
Cls



T=NextUp*16:If T>250 Then T=250
Color 255,T,0
Text 0,590,String$("-",NextUp*6)+">",0,1
	;For a while, I had a Rect here!  Talk about buggering it up!  Nearly got myself disqualified for that!

Color 255,255,255
Text 740,590,"LevelUp--->",1,1
Text 0,584,"Score : "+score,0,1
Text 0,594,"Lives : "+Lives,0,1
If NextUp=>15
	NextUp=NextUp-15
	If MyLev<10 Then MyLev=MyLev+1
	If MyLev=10 Then Score=Score+500
EndIf


	
	Color 250,180,180
	If TDead>0
		TDead=TDead-1
		If (TDead Mod 20) < 10 Then Color 180,250,180
	EndIf
	Text plrx,plry,plev(MyLev),1,1
		
	MySpd=MyLev+1
	If MyLev=10 Then MySpd=14
	If KeyDown(203) Then plrxa=plrxa-1
	If KeyDown(205) Then plrxa=plrxa+1
	If KeyDown(200) Then plrya=plrya-1
	If KeyDown(208) Then plrya=plrya+1
		
	If plrxa>MySpd Then plrxa=myspd
	If plrxa>0 Then plrxa=plrxa-0.25
	If plrxa<0 Then plrxa=plrxa+0.25
	If plrxa<-MySpd Then plrxa=-MySpd
	If Abs(plrxa)<0.3 Then plrxa=0
	plrx=plrx+plrxa
	If plrx<32 Then plrx=32
	If plrx>800-32 Then plrx=800-32

	If plrya>MySpd Then plrya=myspd
	If plrya>0 Then plrya=plrya-0.25
	If plrya<0 Then plrya=plrya+0.25
	If plrya<-MySpd Then plrya=-MySpd
	If Abs(plrya)<0.3 Then plrya=0
	plry=plry+plrya
	If plry<240 Then plry=240
	If plry>600-16 Then plry=600-16

For n=1 To 10
trig(n)=trig(n)+1
If trig(n)=n*4 Then trig(n)=0
Next

	If KeyDown(44) Or KeyDown(45)
			If MyLev<7 And trig(5)=0 Then bul.let=New let:bul\x=plrx:bul\y=plry:bul\u=1:bul\txt$="^":bul\gx=0:bul\gy=-4:bul\pow=1
			
			If MyLev>1 And MyLev<8
				If trig(12-MyLev)=0
						bul.let=New let:bul\x=plrx-18:bul\y=plry:bul\u=1:bul\txt$="!":bul\gx=0:bul\gy=-4:bul\pow=1
						bul.let=New let:bul\x=plrx+18:bul\y=plry:bul\u=1:bul\txt$="!":bul\gx=0:bul\gy=-4:bul\pow=1
				EndIf
			EndIf

			If (MyLev=3 Or MyLev=5) And trig(7)=0
				bul.let=New let:bul\x=plrx-18:bul\y=plry:bul\u=1:bul\txt$="<":bul\gx=-4:bul\gy=0:bul\pow=2
				bul.let=New let:bul\x=plrx+18:bul\y=plry:bul\u=1:bul\txt$=">":bul\gx=4:bul\gy=0:bul\pow=2				
			EndIf
			
			If MyLev>3 And MyLev<9 And trig(10)=0
				bul.let=New let:bul\x=plrx-26:bul\y=plry:bul\u=1:bul\txt$="\":bul\gx=-4:bul\gy=-4:bul\pow=4
				bul.let=New let:bul\x=plrx+26:bul\y=plry:bul\u=1:bul\txt$="/":bul\gx=4:bul\gy=-4:bul\pow=4
			EndIf
			If MyLev>5 And MyLev<9 And trig(10)=20
				bul.let=New let:bul\x=plrx-34:bul\y=plry:bul\u=1:bul\txt$="/":bul\gx=-4:bul\gy=4:bul\pow=4
				bul.let=New let:bul\x=plrx+34:bul\y=plry:bul\u=1:bul\txt$="\":bul\gx=4:bul\gy=4:bul\pow=4
			EndIf
			If MyLev>6 And trig(1)=0 Then bul.let=New let:bul\x=plrx:bul\y=plry:bul\u=1:bul\txt$="^":bul\gx=0:bul\gy=-6:bul\pow=8

			If MyLev=8
				If trig(2)=0
						bul.let=New let:bul\x=plrx-8:bul\y=plry:bul\u=1:bul\txt$="!":bul\gx=0:bul\gy=-4:bul\pow=4
						bul.let=New let:bul\x=plrx+8:bul\y=plry:bul\u=1:bul\txt$="!":bul\gx=0:bul\gy=-4:bul\pow=4
				EndIf
			EndIf
			
			If MyLev=9 Or MyLev=10
						If trig(3)=0 Then bul.let=New let:bul\x=plrx-32:bul\y=plry:bul\u=1:bul\txt$="/\":bul\gx=aimx:bul\gy=aimy:bul\pow=8
						If trig(3)=6 Then bul.let=New let:bul\x=plrx+32:bul\y=plry:bul\u=1:bul\txt$="/\":bul\gx=aimx:bul\gy=aimy:bul\pow=8					
			EndIf
			
			If MyLev=9
				If trig(2)=0
						bul.let=New let:bul\x=plrx-8:bul\y=plry:bul\u=1:bul\txt$="/":bul\gx=4:bul\gy=-4:bul\pow=4
						bul.let=New let:bul\x=plrx+8:bul\y=plry:bul\u=1:bul\txt$="\":bul\gx=-4:bul\gy=-4:bul\pow=4
				EndIf
			EndIf
			If MyLev=10 And trig(1)=2 Then bul.let=New let:bul\x=plrx:bul\y=plry:bul\u=1:bul\txt$="^":bul\gx=0:bul\gy=-6:bul\pow=8

			

			
	EndIf


shoot=shoot+1
If shoot=120
shoot=0


	.outside1
	x1=Rand(-100,900)
	y1=Rand(-100,700)
	If x1>0 And x1<800 And y1>0 And y1<600 Then Goto outside1

	.outside2
	x4=Rand(-100,900)
	y4=Rand(-100,700)
	If x4>0 And x4<800 And y4>0 And y4<600 Then Goto outside2

	x2=Rand(100,700)
	y2=Rand(100,500)
	
	x3=Rand(100,700)
	y3=Rand(100,500)
	speed#=Rnd(0.2,0.5)
	
	r=0
	g=Rand(3,5)*50
	b=Rand(3,5)*50

	t=Rand(1,10)
	
	For n=1 To 8
	
	Bad.Die=New die  ;Ooooooooo!
	
	bad\t=t
	bad\frame=0-(n*15)
	
	bad\r=r
	bad\g=g
	bad\b=b
	
	bad\health=1
	
	bad\speed=speed
	bad\x1=x1:bad\x2=x2:bad\x3=x3:bad\x4=x4
	bad\y1=y1:bad\y2=y2:bad\y3=y3:bad\y4=y4
		
	Next
EndIf

dist=800
tarx=0
tary=0
aimx=0
aimy=-16

For bad.die=Each die
	kill=0
	Color bad\r,bad\g,bad\b
	bad\x=Bezier4(bad\frame,bad\x1,bad\x2,bad\x3,bad\x4)
	bad\y=Bezier4(bad\frame,bad\y1,bad\y2,bad\y3,bad\y4)
	Text bad\x,bad\y,btype$(bad\t),1,1
		
		d2=Sqr( ((plrx-bad\x)*(plrx-bad\x))+((plry-bad\y)*(plry-bad\y)))
		If d2<dist And plry>bad\y And bad\y>0 And bad\x>0 And bad\x<800
			dist=d2
			tarx=bad\x:tary=bad\y
			ang=ATan2(bad\y-plry,bad\x-plrx)
			aimx=Cos(ang)*16:aimy=Sin(ang)*16
		EndIf
		
	bad\frame=bad\frame+bad\speed
	If bad\frame>100 Then kill=1
	
	If Rand(1,250)=1 Then bul.let=New let:bul\x=bad\x:bul\y=bad\y:bul\u=0:bul\txt$="v":bul\gx=0:bul\gy=4:bul\pow=1

	
	
	If bad\health<=0
		kill=1:score=score+25
		pic.kup=New kup
		pic\x=bad\x:pic\y=bad\y:pic\t=240
	EndIf
	
	If kill=1 Then Delete bad.die
Next

For pic.kup=Each kup
	kill=0
	
	Color 80,255,80
	tt$="P"
	pic\t=pic\t-1
	pic\y=pic\y+1
	If pic\t<120 Then tt$="p"
	If pic\t<60 Then tt$="."
	Text pic\x,pic\y,tt$,1,1
	If Abs(pic\x-plrx)<16 And Abs(pic\y-plry)<8 Then kill=1:NextUp=NextUp+1
	If pic\t<=0 Then kill=1
	
	If kill=1 Then Delete pic.kup
	
Next

For bul.let=Each let
	kill=0
	Color 255,255,255
	bul\x=bul\x+bul\gx
	bul\y=bul\y+bul\gy
	Text bul\x,bul\y,bul\txt$,1,1
	If bul\x<-32 Or bul\x>832 Or bul\y<-32 Or bul\y>632 Then kill=1
	
	
	If bul\u=1
		For bad.die=Each die
			k2=0
			If Abs(bul\x-bad\x)<16 And Abs(bul\y-bad\y)<8 Then kill=1:k2=1
						
			If k2=1 Then bad\health=bad\health-bul\pow:score=score+5
		Next
	EndIf
	
	If bul\u=0 And TDead=0
		If Abs(bul\x-plrx)<16 And Abs(bul\y-plry)<8 Then kill=1:lives=lives-1:MyLev=1:NextUp=0:Shield=120:plrx=400:plry=580:TDead=120
	EndIf
	
	If kill=1 Then Delete bul.let
Next


If Lives=-1 Then endofgame=1

Flip
If KeyDown(1) Then endofgame=99
Until endofgame<>0

Color 0,0,0
Text 401,281,"Game Over",1,1
Text 401,321,"Score : "+score,1,1


Color 255,255,255
Text 400,280,"Game Over",1,1
Text 400,320,"Score : "+score,1,1

Flip

Delay 1500



Function Bezier3(Perc#,p1#,p2#,p3#)
If perc<0 Then Return p1
If perc>100 Then Return p3
D1#=(((p2-p1)*perc)/100)+p1
D2#=(((p3-p2)*perc)/100)+p2
D3#=(((d2-d1)*perc)/100)+d1
Return D3
End Function 


Function Bezier4(Perc#,p1#,p2#,p3#,p4#)
If perc<0 Then Return p1
If perc>100 Then Return p4
D1#=(((p2-p1)*perc)/100)+p1
D2#=(((p3-p2)*perc)/100)+p2
D3#=(((p4-p3)*perc)/100)+p3
D4#=Bezier3(perc,D1,D2,D3)
Return D4
End Function