Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|619|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-
Fiery Fourth

by Eikon for Workshop #003
You begin with 5 health, and your mission is to set off as many fireworks as possible before the red guys get you.
AppTitle "Fiery Fourth by Eikon"
Graphics 640, 480, 16, 2
SeedRnd MilliSecs()

Const Dist = 32

Type Obj 
	Field X, Y#, ID, G#, S#, D, A, R#, C[2], W
End Type

Dim Points.Obj((640 / Dist) + 1)

Global pImg = CreateImage(8, 9)
Global eImg = CreateImage(8, 9)
Global gImg = CreateImage(640, 50)

RenderImg
RenderLand

.Again
Global pX = 20, pY = 340, pG# = 0, pJump = False
Global pLife = 5, pScore = 0
Local tmp, eTime = MilliSecs(), bTime, bBlink = False, bFire = False

SetBuffer BackBuffer()
While Not KeyDown(1)

If bBlink = True Then
	If Rand(1, 2) = 1 Then DrawImage pImg, pX, pY
	If MilliSecs() >= bTime + 2000 Then bBlink = False
Else
	DrawImage pImg, pX, pY
EndIf

DrawImage gImg, 0, 430
Color 255, 255, 255: Text 1, 1, "Life: " + pLife
Text 1, 16, "Score: " + pScore

If Not ImagesCollide(pImg, pX, pY, 0, gImg, 0, 430, 0) Then 
	If pG < 2 Then pG = pG + .1
	pY = pY + pG
Else
	pJump = False
EndIf

If KeyDown(203) And pX > 0 Then 
	If ImageRectCollide(gImg, 0, 430, 0, pX - 4, pY + ImageHeight(pImg) - 4, 4, 4) Then pY = pY - 2
	pX = pX - 2
EndIf
If KeyDown(205) And pX < 640 - ImageWidth(pImg) Then 
	If ImageRectCollide(gImg, 0, 430, 0, pX + ImageWidth(pImg), pY + ImageHeight(pImg) - 4, 4, 4) Then pY = pY - 2
	pX = pX + 2
EndIf

If KeyDown(57) And pJump = False Then
	pG = -2: pJump = True
EndIf

If pJump = True Then
	If pG >= 2 Then pG = pG + .1
	pY = pY + pG
EndIf

If MilliSecs() >= eTime + 3000 Then 
	o.Obj = New Obj
	o\X = Rand(0, 620): o\Y = 340: o\ID = 1: o\G = 0
	eTime = MilliSecs()
EndIf

If bFire = False Then
	o.Obj = New Obj
	o\X = Rand(0, 620): o\Y = 340: o\ID = 2: o\G = 0
	bFire = True
EndIf

For o.Obj = Each Obj
	Del = 0
	If o\ID = 1 ; Enemy
		DrawImage eImg, o\X, o\Y
		
		If Rand(0, 100) = 50 Then o\D = Rand(0, 2)
		
		If o\D = 0 Then     ; Left
			If o\X > 0 Then 
				If ImageRectCollide(gImg, 0, 430, 0, o\X - 4, o\Y + ImageHeight(eImg) - 4, 4, 4) Then o\Y = o\Y - 2
				o\X = o\X - 1
			Else
				o\D = 1
			EndIf
		ElseIf o\D = 1 Then ; Right
			If o\X < 640 - ImageWidth(pImg) Then
				If ImageRectCollide(gImg, 0, 430, 0, o\X + ImageWidth(eImg), o\Y + ImageHeight(eImg) - 4, 4, 4) Then o\Y = o\Y - 2
				o\X = o\X + 1
			Else
				o\D = 0
			EndIf
		EndIf
		
		If Not ImagesCollide(eImg, o\X, o\Y, 0, gImg, 0, 430, 0) Then 
			If o\G < 2 Then o\G = o\G + .1
			o\Y = o\Y + o\G
		EndIf

		If ImageRectCollide(eImg, o\X, o\Y, 0, pX, pY + ImageHeight(pImg), ImageWidth(pImg), 1) And pJump = True Then 
			pScore = pScore + 10
			Del = 1
		EndIf
			
		If Del = 0 Then
			If ImageRectCollide(eImg, o\X, o\Y, 0, pX, pY, 1, ImageHeight(pImg)) - 2 And bBlink = False Then
				pLife = pLife - 1
				bTime = MilliSecs(): bBlink = True
			ElseIf ImageRectCollide(eImg, o\X, o\Y, 0, pX + ImageWidth(pImg), pY, 1, ImageHeight(pImg)) - 2 And bBlink = False Then
				pLife = pLife - 1
				bTime = MilliSecs(): bBlink = True
			EndIf 
		EndIf
		
		;Color 255, 0, 0: Rect pX, pY + ImageHeight(pImg), ImageWidth(pImg), 1
		;Rect pX, pY, 1, ImageHeight(pImg) - 2
		;Rect pX + ImageWidth(pImg), pY, 1, ImageHeight(pImg) - 2
		
	ElseIf o\ID = 2 Then ; Firework
		Color 0, 255, 255: Rect o\X, o\Y, 10, 10
		
		If Not ImageRectCollide(gImg, 0, 430, 0, o\X, o\Y, 10, 10) Then 
			If o\G < 2 Then o\G = o\G + .1
			o\Y = o\Y + o\G
		EndIf
		
		If ImageRectCollide(pImg, pX, pY, 0, o\X, o\Y, 10, 10) Then
			CreateFuse o\X, o\Y
			pScore = pScore + 20: bFire = False
			Del = 1
		EndIf
	ElseIf o\ID = 3 Then ; Fuse
		Color 255, 255, 0: Rect o\X, o\Y, 2, 2
		If o\Y > o\S Then 
			o\Y = o\Y - 3
		Else
			CreateFire o\X, o\Y
			Del = 1
		EndIf
	ElseIf o\ID = 4 Then ; Firework
		Color o\C[0], o\C[1], o\C[2]
		Rect o\R * Cos(o\A) + o\X, o\R * Sin(o\A) + o\Y, o\W, o\W
		If o\R >= Rand(20, 50) And o\D = 0 Then CreateFade o\R * Cos(o\A) + o\X, o\R * Sin(o\A) + o\Y, o\C[0], o\C[1], o\C[2], 4: o\D= 1: o\W = 4
		If o\R >= Rand(50, 80) And o\D = 1 Then CreateFade o\R * Cos(o\A) + o\X, o\R * Sin(o\A) + o\Y, o\C[0], o\C[1], o\C[2], 3: o\D = 2: o\W = 3
		If o\R >= Rand(80, 110) And o\D = 2 Then CreateFade o\R * Cos(o\A) + o\X, o\R * Sin(o\A) + o\Y, o\C[0], o\C[1], o\C[2], 2: o\D = 3: o\W = 2
		If o\R >= Rand(110, 140) And o\D = 3 Then CreateFade o\R * Cos(o\A) + o\X, o\R * Sin(o\A) + o\Y, o\C[0], o\C[1], o\C[2], 1: o\D = 4: o\W = 1

		o\R = o\R + o\S: o\Y = o\Y + .5
		If o\C[0] >= 0 Then o\C[0] = o\C[0] - Rand(1, 2)
		If o\C[1] >= 0 Then o\C[1] = o\C[1] - Rand(1, 2)
		If o\C[2] >= 0 Then o\C[2] = o\C[2] - Rand(1, 2)
		If o\C[0] < 0 Then o\C[0] = 0
		If o\C[1] < 0 Then o\C[1] = 0
		If o\C[2] < 0 Then o\C[2] = 0

		If o\C[0] <= 0 And o\C[1] <= 0 And o\C[2] <= 0 Then Del = 1
	ElseIf o\ID = 5 Then ; Fader
		Color o\C[0], o\C[1], o\C[2]
		Rect o\X, o\Y, o\W, o\W

		If o\C[0] >= 0 Then o\C[0] = o\C[0] - Rand(1, 2) Else o\C[0] = 0
		If o\C[1] >= 0 Then o\C[1] = o\C[1] - Rand(1, 2) Else o\C[1] = 0
		If o\C[2] >= 0 Then o\C[2] = o\C[2] - Rand(1, 2) Else o\C[2] = 0
		If o\C[0] < 0 Then o\C[0] = 0
		If o\C[1] < 0 Then o\C[1] = 0
		If o\C[2] < 0 Then o\C[2] = 0

		If o\C[0] <= 0 And o\C[1] <= 0 And o\C[2] <= 0 Then Del = 1			
	EndIf

	If Del = 1 Then Delete o
Next

If pLife <= 0 Then Goto GameOver

;Color 255, 0, 0: Rect pX + ImageWidth(pImg), pY + ImageHeight(pImg) - 4, 4, 4
;Rect pX - 4, pY + ImageHeight(pImg) - 4, 4, 4

Flip: Cls
Wend: End

Function RenderImg()
SetBuffer ImageBuffer(pImg): Cls
Restore playerImage: Color 255, 255, 0
For y = 0 To 8
	For x = 0 To 7
		Read tmp: If tmp = 1 Then Rect x, y, 1, 1
	Next
Next
ScaleImage pImg, 1.5, 1.5

SetBuffer ImageBuffer(eImg): Cls
Restore playerImage: Color 255, 0, 0
For y = 0 To 8
	For x = 0 To 7
		Read tmp: If tmp = 1 Then Rect x, y, 1, 1
	Next
Next
ScaleImage eImg, 1.5, 1.5

End Function

Function RenderLand()
SetBuffer ImageBuffer(gImg): Cls
tmp = 1
For i = 0 To 640 Step Dist    ; Create points
	Points.Obj(tmp) = New Obj ; Create type
	Points(tmp)\X = i
	Points(tmp)\Y = 50 - Rand(20, 50)
	tmp = tmp + 1
Next
Color 0, 178, 0
For i = 1 To tmp - 1
	If i <> 1 Then Line Points(i - 1)\X, Points(i - 1)\Y, Points(i)\X, Points(i)\Y
	If i <> 1 Then Line Points(i - 1)\X, Points(i - 1)\Y + 1, Points(i)\X, Points(i)\Y + 1
	If i <> 1 Then Line Points(i - 1)\X, Points(i - 1)\Y + 1, Points(i)\X, Points(i)\Y + 2
	If i <> 1 Then Line Points(i - 1)\X, Points(i - 1)\Y + 1, Points(i)\X, Points(i)\Y + 3
Next

End Function

Function CreateFuse(x, y)
	o.Obj = New Obj
	o\X = X + 4: o\Y = Y: o\ID = 3: o\S = Rand(50, 250)
End Function

Function CreateFire(x, y)
	tmp1 = Rand(100, 255): tmp2 = Rand(100, 255): tmp3 = Rand(100, 255)
	For i = 0 To 50
		o.Obj = New Obj
		o\X = X: o\Y = Y: o\A = Rand(0, 359): o\W = 5
		o\R = 0: o\S = Rnd(.1, 2): o\ID = 4: o\D = 0
		o\C[0] = tmp1: o\C[1] = tmp2: o\C[2] = tmp3
	Next
End Function

Function CreateFade(x, y, c1, c2, c3, w)
	o.Obj = New Obj
	o\ID = 5: o\W = w: o\A = a: o\R = R: o\S = S
	o\X = x: o\Y = y
	o\C[0] = c1: o\C[1] = c2: o\C[2] = c3
End Function

.GameOver
FlushKeys()
Repeat
Color 255, 255, 255: Text 1, 1, "You have died while valiantly fighting for your country."
Color 255, 255, 0: Text 1, 16, "Final Score: " + pScore
Color 0, 255, 255: Text 1, 48, "Press ENTER to try again, or ESCAPE to exit"

If KeyDown(1) Then End

Flip: Cls
Until KeyDown(28)
Delete Each Obj
Goto Again

.playerImage
Data 0,1,1,1,1,1,1,0
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,0,1,1,0,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,0,0,0,0,1,1
Data 1,1,1,0,0,1,1,1
Data 1,1,1,1,1,1,1,1
Data 0,1,1,1,1,1,1,0