Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|527|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Space Snake

by JL235 for Workshop #062

Guide the snake to collect the objects

Q/A = Left W/S = Right

Click to download this entry

One Button Missile Command

by JL235 for Workshop #071

Feel free to mess with the constants to see if you can make it work better or what.

Space to shoot. Space to detonate.

Graphics 800,600,0,2
AppTitle "one-button missile command"
SetBuffer BackBuffer()

;general info
Const PointsAdd# = 0.1
Global points# = 100
Global score = 0
Global gameoverFlag = False

;player info
Const PlayerSize = 35
Const PlayerLength = 50
Const PlayerSpeedIncrease# = 0.001
Global playerSpeed# = 2.8
Global playerShotType = False
Global playerAngle# = 0

;missile info
Const MissileDelay = 800
Const MissileSpeed = 2
Const MissileSize = 7

Global missileTimer = 0
Global missileX# = GraphicsWidth()/2
Global missileY# = GraphicsHeight()/2
Global missileAngle = playerAngle

;enemy info
Const EnemySize = 5
Const EnemySpeed = 1
Const EnemyGenerateMinimumDelay = 1250

Global enemyGenerateDelay = 3000
Global enemyGenerateTimer = MilliSecs() + enemyGenerateDelay

Type Enemy
	Field x#
	Field y#
	Field angle
End Type

;explosion info
Const ExplosionSpeed# = 2.5
Const ExplosionMinimumSize = 0
Const ExplosionMaximumSize = 90

Type Explosion
	Field x#
	Field y#
	Field size#
End Type


;MAIN LOOP
While Not KeyDown(1)
Cls
	;enemies - check and generate them
	If enemyGenerateTimer < MilliSecs()
		enemy.Enemy = New Enemy
			enemy\angle = Rnd(0,360)
			enemy\x# = GraphicsWidth()/2 - 300*Cos(enemy\angle)
			enemy\y# = GraphicsHeight()/2 - 300*Sin(enemy\angle)
		
		If enemyGenerateDelay > EnemyGenerateMinimumDelay
			enemyGenerateDelay = enemyGenerateDelay - 100
		Else
			enemyGenerateDelay = EnemyGenerateMinimumDelay
		EndIf
		enemyGenerateTimer = MilliSecs() + enemyGenerateDelay
	EndIf
	
	;if space pressed
	If KeyHit(57)
		If playerShotType = False And missileTimer < MilliSecs()
				missileX# = GraphicsWidth()/2
				missileY# = GraphicsHeight()/2
				missileAngle = playerAngle
				missileTimer = MilliSecs() + MissileDelay
				
				playerShotType = True
		ElseIf playerShotType ;if missile
			explosion.Explosion = New Explosion
				explosion\x# = missileX#
				explosion\y# = missileY#
				explosion\size# = ExplosionMinimumSize
				
				playerShotType = False
		EndIf
	EndIf
	
	;missile - move it
	If playerShotType
		missileX# = missileX# - MissileSpeed*Cos(missileAngle)
		missileY# = missileY# - MissileSpeed*Sin(missileAngle)
	
		If missileX# < 0 Or missileY# < 0 Or missileX# > GraphicsWidth() Or missileY# > GraphicsHeight()
			playerShotType = False
		EndIf
	EndIf
	
	;explosion - increase size
	For explosion.Explosion = Each Explosion
		;check for explosion to enemy collision
		For enemy.Enemy = Each Enemy
			If ((enemy\x# - explosion\x#)*(enemy\x# - explosion\x#) + (enemy\y# - explosion\y#)*(enemy\y# - explosion\y#))^0.5 < explosion\size/2
				score = score + Points
				Delete enemy
			EndIf
		Next
		
		If explosion\size# < explosionMaximumSize
			explosion\size# = explosion\size# + explosionSpeed#
		Else
			Delete explosion
		EndIf
	Next
	
	;enemies - move them
	For enemy.Enemy = Each Enemy
		enemy\x# = enemy\x# + EnemySpeed*Cos(enemy\angle)
		enemy\y# = enemy\y# + EnemySpeed*Sin(enemy\angle)
		
		;check for enemy to player collision
		If ((enemy\x# - GraphicsWidth()/2)*(enemy\x# - GraphicsWidth()/2) + (enemy\y# - GraphicsHeight()/2)*(enemy\y# - GraphicsHeight()/2))^0.5 < playerSize/2
			gameoverFlag = True
		EndIf
	Next
	
	;draw explosion
	Color 130,30,30
		For explosion.Explosion = Each Explosion
			Oval explosion\x# - explosion\size/2, explosion\y# - explosion\size/2, explosion\size, explosion\size
		Next
	
	;draw player
	Color 244,244,244
		playerSpeed = playerSpeed + PlayerSpeedIncrease#
		playerAngle# = playerAngle# + playerSpeed#
		Oval GraphicsWidth()/2 - PlayerSize/2, GraphicsHeight()/2 - PlayerSize/2, PlayerSize, PlayerSize
		Line GraphicsWidth()/2, GraphicsHeight()/2, GraphicsWidth()/2 - PlayerLength*Cos(playerAngle#), GraphicsHeight()/2 - PlayerLength*Sin(playerAngle#)
	
	;draw missile
	Color 50,50,180
		If playerShotType
			Rect missileX# - MissileSize/2, missileY# - MissileSize/2, MissileSize, MissileSize
		EndIf
	
	;draw enemies
	Color 60,160,30
		For enemy.Enemy = Each Enemy
			Oval enemy\x# - EnemySize/2, enemy\y# - EnemySize/2, EnemySize, EnemySize
		Next
	
	;write score
	points# = points# + PointsAdd#
	Color 255,255,255
		Text 10,12,"Score: " + score
	
	;if gameover
	If gameoverFlag = True
		Text 10,32,"GAME OVER!"
		Flip
		FlushKeys
		WaitKey
		End
	EndIf
Flip
Wend
End

Missile Command

by JL235 for Workshop #081

Shoot the missiles from out of the sky.

Mouse

// MISSILE COMMAND
// by Joseph Lenton
// 29/12/06

Program
Uses pure2d, keyset

const
    GRAPHICS_WIDTH = 800
    GRAPHICS_HEIGHT = 600
    
    LAND_HEIGHT = 500
    
    BASE_SIZE = 15
    
    PLAYER_MISSILE_SIZE = 3
    PLAYER_MISSILE_SPEED = 4
    PLAYER_MISSILE_COLLISION_OFFSET = 3
    
    MISSILE_SPEED = 3
    MISSILE_SIZE = 3
    MISSILE_RANDOMIZER = 10
    MISSILE_START_ANGLE = 120
    MISSILE_END_ANGLE = 60
    
    EXPLOSION_MAXIMUM_SIZE = 80
    EXPLOSION_SIZE_INCRIMENT = 6

type Bases = record
    x : integer
    y : integer
endtype

type PlayerMissiles = record
    x : real
    y : real
    destinationX : integer
    destinationY : integer
    deltaX : real
    deltaY : real
endtype

type Missiles = record
    x : real
    y : real
    origX : integer
    origY : integer
    deltaX : real
    deltaY : real
endtype

type Explosions = record
    x : integer
    y : integer
    size : integer
endtype 

// draw land
procedure drawLand()
begin
    RectC(0, LAND_HEIGHT, GRAPHICS_WIDTH, GRAPHICS_HEIGHT, ToRGBA(180,60,90), true) 
end

// BASES
// new base
Procedure newBase(x:Integer, y:Integer)
Begin
    base = NewItem(baseList)
    If Assigned(base)
        base.x = x
        base.y = y
    Else 
        MessageBox("Could not add base")
    EndIf
End

// draw bases
procedure drawBases()
begin
    loop base through baseList
        Ellipse(base.x, base.y, BASE_SIZE, BASE_SIZE, ToRGBA(255,255,255), true)
    endloop
end         

// PLAYER MISSILES
// new player missile
procedure newPlayerMissile(x:integer, y:integer, destinationX:integer, destinationY:integer)
var
    angle : real
begin
    playerMissile = newItem(playerMissileList)
    if assigned(playerMissile)
        playerMissile.x = x
        playerMissile.y = y
        playerMissile.destinationX = destinationX
        playerMissile.destinationY = destinationY
        
        angle = atan2(y-destinationY, x-destinationX)
        playerMissile.deltaX = cos(angle)*PLAYER_MISSILE_SPEED
        playerMissile.deltaY = sin(angle)*PLAYER_MISSILE_SPEED
    else
        messagebox("Could not add Player Missile")
    endif
end

// update player missiles
procedure updatePlayerMissiles()
begin
    loop playerMissile through playerMissileList
        playerMissile.x = playerMissile.x-playerMissile.deltaX
        playerMissile.y = playerMissile.y-playerMissile.deltaY
        
        if abs(playerMissile.x-playerMissile.destinationX) < PLAYER_MISSILE_COLLISION_OFFSET
            if abs(playerMissile.y-playerMissile.destinationY) < PLAYER_MISSILE_COLLISION_OFFSET
                newExplosion(playerMissile.x, playerMissile.y)
                free(playerMissile)
            endif
        endif 
    endloop
end

// draw player missiles
procedure drawPlayerMissiles()
begin
    loop playerMissile through playerMissileList
        ellipse(playerMissile.x, playerMissile.y, PLAYER_MISSILE_SIZE, PLAYER_MISSILE_SIZE, torgba(200, 60, 130))
    endloop
end

// MISSILES
// generate new missile
procedure generateNewMissile()
var
    randAngle:integer
    randX:integer
    
begin
    if Rand(0, MISSILE_RANDOMIZER) = 0
        randAngle = Rand(MISSILE_START_ANGLE, MISSILE_END_ANGLE)
        randX = Rand(50, GRAPHICS_WIDTH-50)
         
        newMissile(randAngle, randX, -10)
    endif
end

// new missile
procedure newMissile(angle:integer, x:integer, y:integer)
begin
    missile = newitem(missileList)
    if assigned(missile)
        missile.x = x
        missile.y = y
        missile.origX = x
        missile.origY = y
        
        missile.deltaX = cos(angle)*MISSILE_SPEED
        missile.deltaY = sin(angle)*MISSILE_SPEED 
   Else
        MessageBox("Could not add missile")
   EndIf
end

// draw missiles
procedure drawMissiles()
var
    randColor:integer
    
begin
    loop missile through missileList
        randColor = ToRGBA(Rand(30,225), Rand(30,225), Rand(30,225))
        Line(missile.origX, missile.origY, missile.x, missile.y, randColor)
        Ellipse(missile.x, missile.y, MISSILE_SIZE, MISSILE_SIZE, randColor, true)
    endloop
end

// update missiles
procedure updateMissiles()
begin
    loop missile through missileList
        missile.x = missile.x+missile.deltaX
        missile.y = missile.y+missile.deltaY
        
        if (missile.x < 0) or (missile.x > GRAPHICS_WIDTH) or (missile.y > LAND_HEIGHT)
            free(missile)
        else
            checkMissileBaseCollision(missile)
        endif
    endloop
end

// check missile base collision
procedure checkMissileBaseCollision(localMissile:^Missiles)
begin
    loop base through baseList
        if Abs(base.x-missile.x) < BASE_SIZE/2+MISSILE_SIZE/2
            if Abs(base.y-missile.y) < BASE_SIZE/2+MISSILE_SIZE/2
                free(base)
                free(missile)
                dec(playerLives)
            endif
        endif        
    endloop
end

// EXPLOSION
// new explosion
procedure newExplosion(x:integer, y:integer)
begin
    explosion = newitem(explosionList)
    if assigned(explosion)
        explosion.size = 1
        explosion.x = x
        explosion.y = y
    else
        messagebox("could not make new explosion")
    endif
end

// update explosions
procedure updateExplosions()
var
    x : integer
    y : integer
    
begin
    loop explosion through explosionList
        loop missile through missileList
            x = abs(missile.x-explosion.x)
            y = abs(missile.y-explosion.y)
    
            if sqrt(x*x + y*y) < explosion.size
                free(missile)
            endif
        endloop
        
        explosion.size = explosion.size+EXPLOSION_SIZE_INCRIMENT
        
        if explosion.size > EXPLOSION_MAXIMUM_SIZE
            free(explosion)
        endif
    endloop
end

// draw explosions
procedure drawExplosions()
begin
    loop explosion through explosionList
        ellipse(explosion.x, explosion.y, explosion.size, explosion.size, torgba(255,255,255))
    endloop
end

var
    playerLives : integer
    playerScore : integer
     
    baseList : list of Bases
    base : ^Bases

    playerMissileList : list of PlayerMissiles
    playerMissile : ^PlayerMissiles
    
    missileList : list of Missiles
    missile : ^Missiles
    
    explosionList : list of Explosions
    explosion : ^Explosions
    
    i : integer

Begin 
    OpenScreen(GRAPHICS_WIDTH, GRAPHICS_HEIGHT, 16, False)
    
    playerLives = 5
    
    for i = 1 to playerLives
        newBase(rand(50, GRAPHICS_WIDTH-50), LAND_HEIGHT)
    next   
    
    // main loop
    While (keydown(1)=0) and (playerLives > 0)
        if mousehits(0) > 0
            newPlayerMissile(0, LAND_HEIGHT, mousex(), mousey())
        endif
        if mousehits(1) > 0
            newPlayerMissile(GRAPHICS_WIDTH, LAND_HEIGHT, mousex(), mousey())
        endif
        
        // update everything
        updatePlayerMissiles
        updateExplosions
        generateNewMissile
        updateMissiles
           
        // draw everything
        Cls
        drawLand
        drawExplosions
        drawMissiles
        drawPlayerMissiles
        drawBases
        
        playerScore = playerScore+1
        pencolor(toRgba(255,255,255))
        Text(10, 52, "Score: "+playerScore)
        text(10, 64, "Lives: "+playerLives)
        Flip
    Wend
    
    messagebox("You Scored: " + playerScore)
    CloseScreen
End

Physics Balls

by JL235 for Workshop #082

Not much of a game.

Mouse

Click to download this entry

Pick a card!

by JL235 for Workshop #097

Are you a mind reader? Pick a card to find out!

Keyboard

AppTitle("Pick a card!")

; card type
Type Card
	Field suit$
	Field num$
End Type

; main loop
While Not KeyDown(1)
	myCard.Card = NewRandomCard()
	
	Print "pick a card, any card!"
	
	yourCard.Card = New Card
		
	acceptInput = False
	While Not acceptInput
		suit$ = Input$("pick the suit first (c,d,h,s): ")
		If cardSuitString$(suit$) = ""
			Print "that's not acceptable, try again"
		Else
			yourCard\suit$ = cardSuitString$(suit$)
			acceptInput = True
		EndIf
	Wend
	
	acceptInput = False
	While Not acceptInput
		num$ = Input$("now pick the number (1 to 13): ")
		If CardNumber$(Int(num$)) = ""
			Print "that's not acceptable, try again"
		Else
			yourCard\num$ = CardNumber$(Int(num$))
			acceptInput = True
		EndIf
	Wend
	
	Print ""
	Print "ok, your card is the: "
	PrintCard( yourCard )
	Print ""
	If yourCard\suit$ = myCard\suit$ And yourCard\num$ = myCard\num$
		Print "WOW!, you must be a (pc) mind-reader!"
	Else
		Print "Sorry, that was not my card."
		Print "My card was the:"
		PrintCard( myCard )
	EndIf
	
	Print ""
Wend

Function NewRandomCard.Card()
	Local c.Card = New Card
	
	c\num$ = CardNumber$(Rand(1, 13))
	c\suit$ = CardSuitNum$(Rand(1, 4))

	Return c
End Function

Function PrintCard(card.Card)
	Print "The " + card\num$ + " of " + card\suit$ + "."
End Function

Function CardNumber$(num)
	Select num
	Case 1
		Return "ace"
	Case 2
		Return "two"
	Case 3
		Return "three"
	Case 4
		Return "four"
	Case 5
		Return "five"
	Case 6
		Return "six"
	Case 7
		Return "seven"
	Case 8
		Return "eight"
	Case 9
		Return "nine"
	Case 10
		Return "ten"
	Case 11
		Return "jack"
	Case 12
		Return "queen"
	Case 13
		Return "king"
	Default
		Return ""
	End Select
End Function

Function CardSuitNum$(num)
	Select num
	Case 1
		Return "clubs"
	Case 2
		Return "diamonds"
	Case 3
		Return "hearts"
	Case 4
		Return "spades"
	End Select
End Function

Function CardSuitString$(num$)
	Select num$
	Case "c"
		Return "clubs"
	Case "d"
		Return "diamonds"
	Case "h"
		Return "hearts"
	Case "s"
		Return "spades"
	Default 
		Return ""
	End Select
End Function

Mouse Madness

by JL235 for Workshop #103

Keep the ball inside the square

Mouse

Click to download this entry

Square Surprise

by JL235 for Workshop #141

Keep within the rectangle.

Mouse

; Square Surprise v.1
;	by Joseph Lenton - JL235@Kent.ac.uk
; 9th March 2008, 2:20am
; if used or distributed without credit being given then I'll come and break your legs
;
; Built for Wednesday Workshop 141 - The Rectangle Challenge
; at SoCoder.net

; notes:
;  - the players x, y position is presumed to be equal to the mouse position

	; ### Constants ###
	
; the starting width and height of the computer box
Const SQUARE_WIDTH = 50
Const SQUARE_HEIGHT = 50
Const SQUARE_SPEED# = 2

; the starting player width and height
Const PLAYER_WIDTH = 180
Const PLAYER_HEIGHT = 180

Const SCORE_INCREMENT# = 5.0
Const SCORE_INCREMENT_INCREMENT# = 0.03

Const DEAD_TEXT$ = "You Died!"
Const RESET_TEXT$ = "press any key to restart"

Const COLOR_OFFSET = 50

	; ### Types ###
	
; Color
; represents a color which glows and changes
; (probably should have been called GlowColor like the version I wrote in Java)
Type Color
	Field r.ColorComponent
	Field g.ColorComponent
	Field b.ColorComponent
End Type

; Color Component
; the indevidual glowing component of a color
Type ColorComponent
	Field col#
	Field max
	Field min
	Field inc#
End Type

; Square
; all the data about a square,
Type Square
	; the centre (NOT top-left) of the square on screen
	Field x#, y#
	
	Field destX, destY
	Field deltaX#, deltaY#
	
	; the width and height of the square
	Field w, h
	
	Field col.Color
End Type

; Player
; all the data about the player
Type Player
	; the centre (NOT top-left) of the square on screen
	Field x, y
	
	; CURRENT width, height of player
	Field w, h
	
	Field col.Color
End Type

; Score
; represents the score data in the world,
Type Score
	; the current score
	Field score#
	; how much the score will be incremented by
	Field increment#
	; how much the score increment will be incremented by
	Field increment_increment#
End Type

	; ### Initialize! ###
	
Graphics 800, 600, 0, 2
SetBuffer BackBuffer()
SeedRnd MilliSecs()
AppTitle "Square Surprise!"
	
Local square.Square = Null
Local player.Player = Null
Local score.Score = Null

; when this is true the player is playing the game and the world will be updated
Local alive = False
; when this is true the world will be updated
Local reset = True

	; ### Main Loop! ###
; (it's been too long since I've written that)
While Not KeyDown(1)
	; reset
	If Not alive
		If reset
			player = initializePlayer(player, GraphicsWidth()/2, GraphicsHeight()/2)
			square = initializeSquare(square, GraphicsWidth()/2, GraphicsHeight()/2)
			score = initializeScore(score)
			alive = True
			reset = False
		Else
			; check for a keypress
			reset = GetKey() <> 0
		EndIf
	; update
	Else
		updateSquare(square)
		updatePlayer(player)
		alive = isSquareInsidePlayer(player, square)
		incrementScore(score)
	EndIf
	
	; draw
	Cls
	drawSquare(square)
	drawPlayer(player)
	drawScore(score)
	If Not alive
		drawResetText()
	EndIf
	Flip
Wend
End
; end of program, here on are:

	; ### Function Declarations ###
	
	; ## Initialize Functions ###
	; these functions either reset the given type to it's initial state
	; and return it, or create a new one and set it to it's initial state.
	
; Initialize Score
Function initializeScore.Score(s.Score)
	If s = Null Then s = New Score
	
	s\score# = 0.0
	s\increment# = SCORE_INCREMENT#
	s\increment_increment# = SCORE_INCREMENT_INCREMENT#
	
	Return s
End Function

; Initialize Square
Function initializeSquare.Square(s.Square, x, y)
	If s = Null Then s = New Square
	
	s\x = x
	s\y = y
	
	s\destX = s\x
	s\destY = s\y
	
	s\deltaX = 0
	s\deltaY = 0
	
	s\w = SQUARE_WIDTH
	s\h = SQUARE_HEIGHT
	
	s\col = initializeColor(s\col)
	
	Return s
End Function

; Initialize Player
; x, y - player start position
; creates and returns a new player type with the given location
; and also moves the mouse to the given location
Function initializePlayer.Player(p.Player, x, y)
	If p = Null Then p = New Player
	
	MoveMouse(x, y)
	; position
	p\x = x
	p\y = y
	; size
	p\w = PLAYER_WIDTH
	p\h = PLAYER_HEIGHT
	; color
	p\col = initializeColor(p\col)
	
	Return p
End Function

; Initialize Color
Function initializeColor.Color(col.Color)
	If col = Null Then col = New Color
	
	col\r = initializeColorComponent(col\r)
	col\g = initializeColorComponent(col\g)
	col\b = initializeColorComponent(col\b)
	
	Return col
End Function

; Initialize Color Component
Function initializeColorComponent.ColorComponent(col.ColorComponent)
	If col = Null Then col = New ColorComponent
	
	col\col# = Rand(100, 255)
	col\max = isValidColorComponent(col\col + COLOR_OFFSET)
	col\min = isValidColorComponent(col\col - COLOR_OFFSET)
	col\inc# = Rnd(-3.0, 3.0)
	
	Return col
End Function

; Is Valid Color Component
; a color component is valid if it is greater or equal to 0
; and less or equal to 255.
; If the given colour is valid then it will be returnd.
; If it is not then the closest valid value (0 or 255)
; will be returned instead
Function isValidColorComponent(col)
	If col < 0
		Return 0
	Else If col > 255
		Return 255
	Else
		Return col
	EndIf
End Function

	; ## Update Functions ##

; Update Square
Function updateSquare(s.Square)
	s\x# = s\x# + s\deltaX#
	s\y# = s\y# + s\deltaY#
	
	; if we are moving away from the destination
	If isSquareMovingAwayFromDestination(s)
		setRandomDestination(s)
	EndIf
	
	updateColor(s\col)
End Function

; Is Square Moving Away From Destination
; well, is it?
Function isSquareMovingAwayFromDestination(s.Square)
	Return (s\destX# - s\x#) * s\deltaX# <= 0 Or (s\destY# - s\y#) * s\deltaY# <= 0
End Function

; Set Random Destination
Function setRandomDestination(s.Square)
	; set a new one
	s\destX = Rand(0, GraphicsWidth())
	s\destY = Rand(0, GraphicsHeight())
	Local angle# = ATan2(s\destY-s\y#, s\destX-s\x#)
	s\deltaX# = SQUARE_SPEED*Cos(angle#)
	s\deltaY# = SQUARE_SPEED*Sin(angle#)
End Function

; Update Player
; p - the player to update
; moves the given player to the current mouse co-ordinates on the screen
Function updatePlayer(p.Player)
	p\x = MouseX()
	p\y = MouseY()
	updateColor(p\col)
End Function

; Update Color
Function updateColor(c.Color)
	updateColorComponent(c\r)
	updateColorComponent(c\g)
	updateColorComponent(c\b)
End Function

; Update Color Component
Function updateColorComponent(c.ColorComponent)
	c\col# = c\col# + c\inc#
	
	If c\col# > c\max
		c\col = c\max
		c\inc = -c\inc
	Else If c\col# < c\min
		c\col# = c\min
		c\inc = -c\inc
	EndIf
End Function

; Is Square Inside Player
; p - the player to compare with
; s - the square to compare against
; returns true if the square is completely within the player, false if not.
Function isSquareInsidePlayer(p.Player, s.Square)
	Local w = (p\w-s\w)/2
	Local h = (p\h-s\h)/2
	Return ((s\x-w < p\x) And (s\x+w > p\x) And (s\y-h < p\y) And (s\y+h > p\y))
End Function

; Increment Score
; increments the score and the amount of which it is incremented by
Function incrementScore(score.Score)
	score\increment# = score\increment# + score\increment_increment#
	score\score = score\score + score\increment#
End Function

	; ## Drawing Functions ##

; Set Color
Function setColor(col.Color)
	Color col\r\col, col\g\col, col\b\col
End Function

; Draw Square
Function drawSquare(s.Square)
	setColor(s\col)
	Rect s\x-s\w/2, s\y-s\h/2, s\w, s\h, True
End Function

; Draw Player
Function drawPlayer(p.Player)
	setColor(p\col)
	Rect p\x-p\w/2, p\y-p\h/2, p\w, p\h, False
End Function

; Draw Score
Function drawScore(score.Score)
	Color 255, 255, 255
	Text 5, 5, "Score: " + Int(score\score#)
End Function

; Draw Reset Text
Function drawResetText()
	Local strHeight = (StringHeight(DEAD_TEXT$) + StringHeight(RESET_TEXT$))
	Color 255, 255, 255
	Text (GraphicsWidth()-StringWidth(DEAD_TEXT$))/2, (GraphicsHeight()-strHeight)/2, DEAD_TEXT$
	Text (GraphicsWidth()-StringWidth(RESET_TEXT$))/2, GraphicsHeight()/2, RESET_TEXT$
End Function

	; ## stuff missing from standard command library ##

; Max
; returns the larger of the two values
Function max(a, b)
	If (a > b)
		Return a
	EndIf
	Return b
End Function

; Min
; returns the smaller of the two values
Function min(a, b)
	If (a < b)
		Return a
	EndIf
	Return b
End Function